переосмысление/Re-настройки параметров в запросе MySQL

Question

У меня есть следующий код для вставки данных в таблицу с помощью запроса MySQL в VB.NET

Dim MySqlCmdStr = "INSERT INTO tb_idlink(id1,id2) " & 
    "VALUES (@par1,@par2)" 
MySqlCmd.CommandText = MySqlCmdStr 
Dim checkedItem As Object 
For Each checkedItem In CheckedListBox_1.CheckedItems 
    Try 
     MySqlCmd.Connection = MySqlConn 
     With MySqlCmd 
      .Parameters.AddWithValue("@par1", currentID) 
      .Parameters.AddWithValue("@par2", checkedItem.ToString()) 
     End With 

     MySqlConn.Open() 

     MySqlCmd.ExecuteNonQuery() 
     MySqlConn.Close() 
    Catch ex As MySqlException 
     MessageBox.Show(ex.Message) 
    End Try 
Next 

Моя проблема в том, если у меня есть более чем один ящик проверено в CheckedListBox_1, а затем во втором цикле исключение, которое говорит что-то вроде «параметр @ par1 уже определен». Есть ли способ переопределить его? Я не совсем знаком со всем API.

Кроме того, я не уверен на 100%, если петля это лучший способ сделать это, но это первое, что появилось в моей голове. Не стесняйтесь предлагать альтернативный способ сделать это.

Answer 1

Вы не переопределять параметры, вы просто поставить новое значение:

Dim SQL = "INSERT INTO tb_idlink (id1,id2) VALUES (@par1,@par2)" 

Using dbcon As New MySqlConnection(MySQLConnStr) 
    Using cmd As New MySqlCommand(SQL, dbcon) 

     ' define the parameter names and types 
     cmd.Parameters.Add("@par1", MySqlDbType.Int32) 
     cmd.Parameters.Add("@par2", MySqlDbType.Int32) ' ???? 

     dbcon.Open() 
     For Each checkedItem In CheckedListBox1.CheckedItems 
      ' provide the parameter values 
      cmd.Parameters("@par1").Value = currentID 
      cmd.Parameters("@par2").Value = Convert.ToInt32(checkedItem) 
      cmd.ExecuteNonQuery() 
     Next 
    End Using 
End Using 

• Ваш код появляется повторно глобальное соединение, которое опрометчиво. Выше использует Using блоки для создания, использования и и распоряжаться DbConnection и DbCommand объектов в наименьшем объеме возможного
• Вы должны благоприятствовать Add, а не AddWithValue так что вы можете указать тип данных, а не заставляя БД поставщика догадку и уменьшить вероятность ошибок несоответствия типа данных.
• Эти типы данных являются предположениями; CurrentId нигде не определяется и задается имена, оба кажутся целыми, а не строками.