Вставить элемент в качестве дочернего элемента в существующий XML с помощью Xquery

Ex:

<note> 
<to>Tove</to> 
<from>Jani</from> 
<heading>Reminder</heading> 
<body>Don't forget me this weekend!</body> 
</note>

выше XML должен быть обновлен путем добавления нового элемента адреса.

<note> 
    <to>Tove</to> 
    <from>Jani</from> 
    <heading>Reminder</heading> 
    <body>Don't forget me this weekend!</body> 
    <address>Address</address> 
</note>

Это нужно сделать, используя XQuery.

Я refered к this stackoverflow link

Пожалуйста посоветуйте.

источник

2016-12-14 Tushar Banne

раствор, XQuery 1,0 будет использовать рекурсивную функцию typeswitch:

declare function local:insert-address($nodes as node()*) 
{ 
for $node in $nodes 
return 
    typeswitch($node) 
     case element(note) 
      return 
       element { name($node) } { 
        $node/@*, 
        local:insert-address($node/node()), 
        element address { "Address" } 
       } 
     case element() 
      return 
       element { name($node) } { 
        $node/@*, 
        local:insert-address($node/node()) 
       } 
     default 
      return $node 
}; 

let $doc := 
    <note> 
    <to>Tove</to> 
    <from>Jani</from> 
    <heading>Reminder</heading> 
    <body>Don't forget me this weekend!</body> 
    </note> 

return 
    local:insert-address($doc)

В зависимости от того, что XQuery двигатель вы используете, могут быть более простые решения, если ваш процессор поддерживает XQuery Update, как ответ Александра Петрова, или пользовательские функции, такие как MarkLogic's xdmp:node-insert-child().

источник

2016-12-15 01:23:55

Попробуйте это:

copy $note := 
<note> 
    <to>Tove</to> 
    <from>Jani</from> 
    <heading>Reminder</heading> 
    <body>Don't forget me this weekend!</body> 
</note> 

modify (insert node <address>Address</address> into $note) 

return $note

источник

2016-12-14 20:34:39

Вставить элемент в качестве дочернего элемента в существующий XML с помощью Xquery

ответ

Смежные вопросы