Non-throwing версия Seq.exactlyOne для проверки последовательности однократных сигналов

Question

Обновление: Я создал запрос UserVoice для этого: Expand on the Cardinality functions for Seq.

Мне нужна функциональность Seq.exactlyOne, но с семантикой Some/None. Другими словами, мне нужен либо Seq.head, либо, если последовательность пуста или содержит более одного элемента, мне ничего не нужно. Использование Seq.exactlyOne будет забрасывать в таких случаях.

Я не думаю, что есть встроенный способ получить это (хотя это звучит так тривиально, что можно было бы ожидать, что есть аналог для Seq.singleton). Я придумал это, но он чувствует себя запутанным:

let trySingleton sq = 
    match Seq.isEmpty sq with 
    | true -> None 
    | false -> 
     match sq |> Seq.indexed |> Seq.tryFind (fst >> ((=) 1)) with 
     | Some _ -> None 
     | None -> Seq.exactlyOne sq |> Some 

Дает:

> trySingleton [|1;2;3|];; 
val it : int option = None 
> trySingleton Seq.empty<int>;; 
val it : int option = None 
> trySingleton [|1|];; 
val it : int option = Some 1 

Есть более простой, или даже встроенный в путь? Я мог бы попробовать/поймать на Seq.exactlyOne, но это построение бизнес-логики вокруг исключений, я бы предпочел (и это дорого).

UPDATE: я не был осведомлен о функции Seq.tryItem, что бы сделать это проще:

let trySingleton sq = 
    match sq |> Seq.tryItem 1 with 
    | Some _ -> None 
    | None -> Seq.tryHead sq 

(лучше, но он по-прежнему чувствует себя довольно неловко)

Answer 1

Почему бы не подойти к проблема, требуя переустройства счетчика?

let trySingleton' (xs : seq<_>) = 
    use en = xs.GetEnumerator() 
    if en.MoveNext() then 
     let res = en.Current 
     if en.MoveNext() then None 
     else Some res 
    else None 

trySingleton' Seq.empty<int> // None 
trySingleton' [1]    // Some 1 
trySingleton' [1;2]    // None 

Answer 2

Я не знаю о встроенной функции для этого, но вот альтернативный способ ее реализации:

let tryExactlyOne xs = 
    match xs |> Seq.truncate 2 |> Seq.toList with 
    | [x] -> Some x 
    | _ -> None 

FSI демо:

> [42] |> List.toSeq |> tryExactlyOne;; 
val it : int option = Some 42 

> [42; 1337] |> List.toSeq |> tryExactlyOne;; 
val it : int option = None 

> Seq.empty<int> |> tryExactlyOne;; 
val it : int option = None