URL-монитор продолжает увеличивать использование памяти

Question

Я написал программу мониторинга URL-адресов в vb, используя .net 4.0. В основном он устанавливает таймер, который проверяет URL каждые 60 минут, используя htpwebreques/httpwebresponse, и отправляет электронное письмо, если URL-адрес не работает. Однако память, используемая приложением, постоянно увеличивается каждый раз, когда URL проверяется. Это, очевидно, в конечном итоге вызовет проблему, так как приложение предназначено для постоянного мониторинга веб-сайта на предмет доступности, и в конечном итоге на компьютере мониторинга не хватит ресурсов.

Код для моей процедуры CheckURL ниже. Любые советы очень ценятся, спасибо заранее.

Private Sub checkURL() 
    Timer1.Stop() 
    Dim wReq As HttpWebRequest 
    Dim wResp As HttpWebResponse ' WebResponse 

    wReq = HttpWebRequest.Create(url) 
    wReq.Method = "HEAD" 
    Try 
     wResp = wReq.GetResponse() 
     If wResp.StatusCode = 200 Then 
       txtResponse.Text = wResp.StatusCode & ": " & wResp.StatusDescription & vbNewLine & "The " & siteName & " is up" 

       'Only send success results if specified 
       If sendOnFailure = False Then 
        sendResults = True 
       End If 
      Else txtResponse.Text = "There may be a problem with the " & siteName & vbNewLine & "Please verify manually that it is operational." & vbNewLine & "The response received was:" & vbNewLine & "Status Code: " & wResp.StatusCode & " - " & wResp.StatusDescription 
       sendResults = True 
      End If 

     wResp.Close() 
     wResp = Nothing 
     wReq = Nothing 

    Catch ex As Exception 
      txtResponse.Text = "There may be a problem with the " & siteName & vbNewLine & "The error returned was:" & vbNewLine & ex.ToString 
      sendResults = True 

    End Try 

    txtLastCheck.Text = Now.ToString("d MMM yyyy HH:mm") 
    setNextCheck() 

End Sub 

Answer 1

Во-первых, вы должны использовать Option Strict On, который покажет вам, где у вас есть переменные несоответствия типов и может даже предложить исправления для вас, например, увидеть, где оператор DirectCast используется в следующем коде.

Во-вторых, HttpWebResponse имеет метод .Dispose(), так что вы должны позвонить, что, когда вы закончили использовать его, или, как Zaggler отметил, вы можете использовать Using для обеспечения того, чтобы неуправляемые ресурсы очищаются должным образом, тем самым устраняя утечку памяти вы обеспокоены. Обратите внимание, что в коде могут быть другие подобные проблемы, которые мы не видим.

Вы должны не набор вещей, чтобы Nothing в попытке избавиться от них - делать это портит с сборщика мусора и не делает ничего, чтобы обеспечить их чистой утилизации.

Option Strict On 
' .... 

Private Sub checkURL() 
    timer1.Stop() 
    Dim wReq As HttpWebRequest = DirectCast(HttpWebRequest.Create(url), HttpWebRequest) 
    wReq.Method = "HEAD" 

    Try 
     Using wResp As HttpWebResponse = DirectCast(wReq.GetResponse(), HttpWebResponse) 

      If wResp.StatusCode = 200 Then 
       txtResponse.Text = wResp.StatusCode & ": " & wResp.StatusDescription & vbNewLine & "The " & siteName & " is up" 

       'Only send success results if specified 
       If sendOnFailure = False Then 
        sendResults = True 
       End If 
      Else txtResponse.Text = "There may be a problem with the " & siteName & vbNewLine & "Please verify manually that it is operational." & vbNewLine & "The response received was:" & vbNewLine & "Status Code: " & wResp.StatusCode & " - " & wResp.StatusDescription 
       sendResults = True 
      End If 

      wResp.Close() 
     End Using 

    Catch ex As Exception 
     txtResponse.Text = "There may be a problem with the " & siteName & vbNewLine & "The error returned was:" & vbNewLine & ex.ToString 
     sendResults = True 

    End Try 

    txtLastCheck.Text = Now.ToString("d MMM yyyy HH:mm") 
    setNextCheck() 

End Sub