Как обрабатывать нажатые и выпущенные сигналы в перекрывающихся Mousareas?

Question

Я хочу обрабатывать нажатые и выпущенные сигналы в двух перекрывающихся Mouseareas.

Краткое объяснение моего дела заключается в следующем:

У меня есть две области мыши M1 и M2. M1 содержится в прямоугольнике, который служит в качестве кнопки. Он имеет фиксированный размер, например, 100x100. M2 заполняет весь экран и определенно больше по размеру, чем M1. Я могу задавать z-свойства M1 и M2 произвольно. Мне нужно обрабатывать нажатые и выпущенные сигналы в обоих этих Mouseareas.

Возможно ли это в QtQuick и если да, то как?

import QtQuick 2.5 
Item { 
    visible: true 
    width:1280 
    height:720 

    Rectangle { 
     color: "blue" 
     width: 100; height: 100 
     z:1 
     MouseArea { 
      id:m1 
      anchors.fill: parent 
      onPressed : { 
       mouse.accepted = false 
       console.log("pressed m1") 
      } 
      onReleased: { 
       console.log("released m1") 
      } 
     } 
    } 

    MouseArea { 
     id: m2 
     anchors.fill: parent 
     onPressed : { 
      console.log("pressed m2") 
     } 
     onReleased: { 
      console.log("released m2") 
     } 
    } 
} 

Я хочу нажать и отпустить для обеих Mouseareas, когда m1 нажат и отпущен.

(Qt версии 5.5)

Answer 1

Прежде всего, id s не может начинаться с прописных букв, так что ваши MouseArea s не может быть M1 и M2. Вместо этого они должны быть m1 и m2.

import QtQuick 2.3 

Rectangle { 
    id: root 
    width: 400 
    height: 300 

    Rectangle { 
     id: m1Container 
     width: 100 
     height: 100 
     color: "blue" 
     z: 1 

     MouseArea { 
      id: m1 
      anchors.fill: parent 
      hoverEnabled: true 

      onPressed: { 
       mouse.accepted = false 
       console.log("m1 pressed") 
      } 
      onReleased: { 
       console.log("m1 released") 
      } 
     } 
    } 

    MouseArea { 
     id: m2 
     anchors.fill: parent 

     onPressed: { 
      console.log("m2 pressed") 
     } 
     onReleased: { 
      console.log("m2 released") 
      if(m1.containsMouse) { 
       m1.released(mouse) 
      } 
     } 
    } 
} 

Edit: Я заимствовал идею m1.released(mouse) от ответа по sk2212, и отлажен немного обработать случай, когда мышь находится вне m1 и нажимается и отпускается.

Answer 2

После комментариев в первом ответе. Что-то вроде этого:

import QtQuick 2.5 
import QtQuick.Window 2.2 

Window { 
    visible: true 
    width:1280 
    height:720 

    Rectangle { 
     color: "blue" 
     width: 100; height: 100 
     z:1 
     MouseArea { 
      id:m1 
      anchors.fill: parent 
      propagateComposedEvents: true 
      onPressed : { 
       mouse.accepted = false 
       console.log("pressed m1") 
      } 
      onReleased: { 
       console.log("released m1") 

      } 
     } 
    } 

    MouseArea { 
     id: m2 
     anchors.fill: parent 
     onPressed : { 
      console.log("pressed m2") 
     } 
     onReleased: { 
      console.log("released m2") 
      m1.released(mouse); 
     } 
    } 
} 

Это печатает то, что вы хотите.