cscript.exe открывает окно

Question

У меня есть файл vbs, который нужно запускать в 32-разрядной версии, хотя я использую 64-разрядную версию Windows 7. Я могу запустить этот файл с помощью команды

C:\Windows\SysWOW64\cscript.exe my-file.vbs 

и что работает хорошо, но это оставляет меня с проворным окном лишних команд, что я должен закрыть вручную каждый раз. Это также очень затрудняет запуск этого vbs-файла в качестве элемента запуска.

Есть ли способ запустить мой 32-битный vbs-файл в фоновом режиме?

Answer 1

Попробуйте для задачи 64-битной, если он работает вы ок п объединить его с другими ответами

EDIT: здесь вопрос, который идет более подробно на 32/64 битном выпуске

How do I check if wscript/cscript runs on x64 host OS?

здесь модифицированная версия, должна убедиться, что скрипт работает на 64-битных платформа

On Error Resume Next 
Dim WshShell, OsType 
Set WshShell = CreateObject("WScript.Shell") 
OsType = WshShell.RegRead("HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment\PROCESSOR_ARCHITECTURE") 
If OsType = "x86" then 
    wscript.echo "Windows 32bit system detected" 
else 
    wscript.echo "Windows 64bit system detected" 
    If InStr(LCase(WScript.FullName),"system32") Then 
    CreateObject("WScript.Shell").Run """%systemroot%\SysWOW64\wscript.exe"" """ & WScript.ScriptFullName & """" 
    Wscript.Quit 
    End If 
end if 

Msgbox("I ran..") 

Answer 2

Если вы можете использовать WScript вы могли бы сделать следующее, это самый простой подход

Set objShell = CreateObject("Wscript.Shell") 
objShell.Run "Wscript.exe h:\Script\Test1.vbs" 

на самом деле вы можете сделать это как однострочника (я Рубин парень 8>)

CreateObject("Wscript.Shell").Run("Wscript.exe h:\Script\Test1.vbs") 

Answer 3

Если вам нужно использовать Cscript это ИМХО прохладное решение

Const HIDDEN_WINDOW = 0 

strComputer = "." 

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2") 

Set objStartup = objWMIService.Get("Win32_ProcessStartup") 
Set objConfig = objStartup.SpawnInstance_ 
objConfig.ShowWindow = HIDDEN_WINDOW 

Set objProcess = GetObject("winmgmts:\\" & strComputer & "\root\cimv2:Win32_Process") 

objProcess.Create "Cscript.exe h:\Script\Test1.vbs", null, objConfig, intProcessID