Язык правил Drools Fusion: правило шагомера

Question

Я новичок в Drools (версия 6.3), и у меня есть проблемы с конкретным правилом. У меня есть класс под названием «Шаги» с простым полем double steps;. Каждый шаг события представляют собой шаги, предпринятые после предыдущего события и У меня есть рабочее правило, которое говорит, что вы должны двигаться, когда вы не делаете 50 шагов в последний час:

declare Steps 
    @role(event) 
end 

rule "STEPS RULE" 
when 
    $totalSteps : Number(doubleValue < 50) from accumulate(
     Steps(stepsCount : steps) over window:time(1h) from entry-point  
    "entrySteps", sum(stepsCount)) 

then 
    System.out.println("STEPS RULE: get moving!"); 
end 

Теперь вместо того, чтобы каждый событие - это шаги, предпринятые после предыдущего события, я хочу, чтобы они представляли собой кумулятивные шаги. Поэтому, если событие имеет 50 шагов, и вы делаете 20 шагов, я хочу, чтобы следующее событие состояло из 70 шагов. Вопрос в том, как я могу изменить свое правило, чтобы оно все равно работало?

Answer 1

Для шагомера вам понадобится другой класс, отличный от Шагов, класс вашего мероприятия. Правила обновления вашего шагомера просты.

rule "create pedometer" 
when 
    Steps($s: steps) 
    not Pedometer() 
then 
    insert(new Pedometer($s)); 
end 

rule "update pedometer" 
no-loop 
when 
    Steps($s: steps) 
    $p: Pedometer($r: readout) 
then 
    modify($p){ 
     setReadout($r + $s) 
    } 
end 

Edit Если Steps уже содержит накопленные значения, это немного сложнее, так как вам нужно вычислить разницу между первым и последними показаниями шагомера в окне.

rule "ACC STEPS RULE" 
when 
    accumulate(Steps($s : steps) 
       over window:time(1h) from entry-point "entrySteps"; 
     $fst: min($s), $lst: max($s); 
     $lst - $fst < 50) 
then 
    System.out.println("STEPS RULE: get moving!"); 
end 

Должно быть не менее одного чтения в час или другого правила, определяющего эту ситуацию.