Как получить возможные роли/права ACL в папке с помощью CMD?

Question

Я хотел бы знать, как получить возможные права на папку с помощью cmd?

Я попытаюсь объяснить больше мою потребность так, чтобы вы поняли мой вопрос:

Я использую Icacls изменить ACL на MyFolder.

Я использую команду, как это:

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r Administrators:F 

или

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r Users:(OI)(CI)F /t /c 

Проблема заключается в том, что если я бегу, что на французском компьютере это дает мне что-то ошибки апробация вроде: " Не удалось установить доверительные отношения между этой рабочей станцией и основным доменом »....

После выполнения некоторых тестов я понял, что проблема в том, что я использую Administrator s и мне пришлось использовать Administrateur (при запуске моего скрипта на французской Windows).

То же самое для «Пользователей», я должен использовать «Utilisateurs», а не «Пользователи» в моей команде, чтобы он работал.

Мне нужно знать, есть ли переменная, используемая Windows, чтобы помочь мне в локализации, автоматически получать роли с помощью cmd, чтобы заменить «Администраторы», «Пользователи» этой переменной, чтобы мой код работал на любой Windows, все, что это язык ...

что мне нужно что-то вроде:

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r %Admin%:F 


icacls "%ProgramFiles(x86)%\MyFolder" /grant:r %Users%:F 

так что% Администратор% будет заменен автоматически Администраторов на английский компьютер и Administrateur на французском компьютере и так далее.

Полный синтаксис, который я использую на самом деле:

icacls "%ProgramFiles(x86)%\MYFOLDER" /grant:r Administrators:F /grant:r SYSTEM:F /grant Users:(OI)(CI)F /t /c 

Answer 1

Вы можете использовать well known SID string constants

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r *BA:F 

Если имена требуются для других целей, то вы можете запросить WMI для требуемого информация

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    for /f "tokens=2 delims==" %%a in (' 
     wmic path WIN32_UserAccount 
     where ( 
        LocalAccount^="True" 
        And SID Like "S-1-5-21-%%-500" 
       ^) 
     get Name /value 
    ') do for /f delims^=^ eol^= %%b in ("%%a") do set "adminName=%%b" 

    echo Local administrator account = [%adminName%] 


    for /f "tokens=2 delims==" %%a in (' 
     wmic path WIN32_Group 
     where (
        SID Like "S-1-5-32-544" 
       ^) 
     get  Name /value 
    ') do for /f delims^=^ eol^= %%b in ("%%a") do set "adminGroup=%%b" 

    echo Local administrators group = [%adminGroup%] 


    for /f "tokens=2 delims==" %%a in (' 
     wmic path WIN32_Group 
     where (
        SID Like "S-1-5-32-545" 
       ^) 
     get  Name /value 
    ') do for /f delims^=^ eol^= %%b in ("%%a") do set "usersGroup=%%b" 

    echo Local users group   = [%usersGroup%]