Передача массива аргументов в CallByName VBA

Question

Я использую callByName I VBA для динамического вызова разных методов класса. В зависимости от метода у меня будет другое количество аргументов, которые будут храниться в массиве. К сожалению, CallByName принимает массив параметров, поэтому передать переменное число не просто. Есть ли способ обойти это, я нашел решение с использованием информационной библиотеки типов, но это не работает на VBA, хотя я добавил его в качестве ссылки. Ниже приводится иллюстрация того, что я хочу

Public Sub Initialize_Object(ByRef TaskObject, Task_Collection) 

Dim Task_begin As Variant, Method_Parameters As Variant 

Task_begin = Task_Collection("Method") 

CallByName TaskObject, Task_begin, VbMethod, Method_Parameters 

Answer 1

Вы не можете сделать это динамически, поскольку различные методы требуют различного количества аргументов, и вы не можете передать аргументы, где они не ожидали.

Если вы знаете количество аргументов требуется, то вы могли бы назвать каждый элемент массива и передать:

CallByName TaskObject, Task_begin, VbMethod, Method_Parameters(0), Method_Parameters(1), Method_Parameters(2) 

но вы, вероятно, придется создать Select Case блок или подобный обрабатывать все различные методы:

Select Case Method_Name 
    Case "Method_1": CallByName TaskObject, Task_begin, VbMethod, Method_Parameters(0), Method_Parameters(1) 
    Case "Method_2": CallByName TaskObject, Task_begin, VbMethod, Method_Parameters(0) 
    Case "Method_3": CallByName TaskObject, Task_begin, VbMethod, Method_Parameters(0), Method_Parameters(1), Method_Parameters(2) 
End Select 

Какой может быть довольно грязным.

Answer 2

Вы можете использовать CallByName с массивом в качестве аргумента, изменив сигнатуру метода:

#If VBA7 Or Win64 Then 
    Private Declare PtrSafe Function rtcCallByName Lib "VBE7.DLL" (_ 
    ByVal Object As Object, _ 
    ByVal ProcName As LongPtr, _ 
    ByVal CallType As VbCallType, _ 
    ByRef args() As Any, _ 
    Optional ByVal lcid As Long) As Variant 
#Else 
    Private Declare Function rtcCallByName Lib "VBE6.DLL" (_ 
    ByVal Object As Object, _ 
    ByVal ProcName As Long, _ 
    ByVal CallType As VbCallType, _ 
    ByRef args() As Any, _ 
    Optional ByVal lcid As Long) As Variant 
#End If 

Public Function CallByName2(Object As Object, ProcName As String, args() As Variant) 
    AssignResult CallByName2, rtcCallByName(Object, StrPtr(ProcName), VbMethod, args) 
End Function 

Private Sub AssignResult(target, result) 
    If VBA.IsObject(result) Then Set target = result Else target = result 
End Sub 

Вот пример использования:

Sub UsageExample() 
    Dim obj As Object, arguments() 

    Dim obj As New Class1 
    arguments = Array(1, 3) 

    CallByName2 obj, "MyMethod", arguments 
End Sub