перед сохранением события, нужна помощь для циклизации двух ячеек в то же время

Question

Я пытаюсь выполнить событие beforesave, не позволяя пользователям сохранять, если одна из двух заданных ячеек пуста. То, что мне удалось сделать до сих пор, - это соединение столбца 13 (M) и ячейки A4.

Что бы я хотел сделать, это применить событие к комбинации из двух диапазонов и строк, A4-A19 и M4-M19. Таким образом: если A4 не пуст, а M4 пуст, появляется msgbox и блокирует сохранение и т. Д. A5-M5, A6-M6 ... до A19-M19. Если обе соответствующие ячейки пусты в одно и то же время, то сохранение должно быть возможным.

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 

    Dim i As Integer, MyWb As Object 
    i = 13 
    Set MyWb = ThisWorkbook.Sheets("Planning").Cells 
    Do While MyWb(4, i).Value <> "" 
    i = i + 1 
    Loop 
    If i = 13 Then 
     If ThisWorkbook.Sheets("Planning").Range("A4") <> "" Then 
      MsgBox ("You will need to enter topics before saving"), vbCritical 
      Cancel = True 
     End If 
    End If 
End Sub 

на основе кода Wolfie, я сумел получить то, что я хотел, просто добавив Если не IsEmpty для столбца и замены 19 вместо 13.

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 

Dim plansht As Worksheet 
Set plansht = ThisWorkbook.Sheets("Planning") 

' Loop over rows 
Dim rw As Integer 
For rw = 4 To 19 
    ' Test if both the A and M column in row "rw" are blank 
    If Not IsEmpty(plansht.Range("A" & rw)) And plansht.Range("M" & rw).Value = "" Then 
     MsgBox ("You will need to enter topics before saving"), vbCritical 
     Cancel = True 
    End If 
Next rw 

End Sub 

Answer 1

Вы можете цикл по строкам, а просто проверить A и M столбцов, чтобы проверить, если они оба поля пустыми для данной строки. Смотрите ниже код ...

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 

Dim plansht as Worksheet 
Set plansht = ThisWorkbook.Sheets("Planning") 

' Loop over rows 
Dim rw as Integer 
For rw = 4 to 13 
    ' Test if both the A and M column in row "rw" are blank 
    If plansht.Range("A" & rw).Value = "" And plansht.Range("M" & rw).Value = "" Then 
     MsgBox ("You will need to enter topics before saving"), vbCritical 
     Cancel = True 
    End If  
Next rw 

End Sub 

---

Edit:

Ваша правка предложил вы хотите несколько различных комбинаций ячеек порожняком. Вот некоторые примеры If заявления различных результатов

' If BOTH are empty 
If plansht.Range("A" & rw).Value = "" And plansht.Range("M" & rw).Value = "" Then ... 

If IsEmpty(plansht.Range("A" & rw)) And IsEmpty(plansht.Range("M" & rw)) Then ... 

' If EITHER is empty 
If plansht.Range("A" & rw).Value = "" OR plansht.Range("M" & rw).Value = "" Then ... 

If IsEmpty(plansht.Range("A" & rw)) Or IsEmpty(plansht.Range("M" & rw)) Then ... 

' If BOTH are NOT empty 
If plansht.Range("A" & rw).Value <> "" And plansht.Range("M" & rw).Value <> "" Then ... 

If Not IsEmpty(plansht.Range("A" & rw)) And Not IsEmpty(plansht.Range("M" & rw)) Then ... 

Обратите внимание, что при запуске введения Not с несколькими условиями, логика может быстро стать трудно интерпретировать. Вы можете использовать скобки в условиях группы с Not, но вы получите такие вещи, как этот смысл тот же логически:

If Not IsEmpty(plansht.Range("A" & rw)) And Not IsEmpty(plansht.Range("M" & rw)) Then ... 
If Not (IsEmpty(plansht.Range("A" & rw)) Or IsEmpty(plansht.Range("M" & rw))) Then ... 

Answer 2

Дайте этому попытку:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 

    Const FIRST_ROW as integer = 4 
    Const LAST_ROW as integer = 19 
    Const ColA As Integer = 4 
    Const ColM as integer = 13 
    Dim MyWb As Worksheet 
    Dim CurRow as Integer 

    Set MyWb = ThisWorkbook.Sheets("Planning") 
    For CurRow = FIRST_ROW to LAST_ROW 
     If len(mywb.cells(CurRow, ColA)) = 0 and len(mywb.cells(CurRow, ColM)) = 0 then 
     MsgBox ("You will need to enter topics before saving"), vbCritical 
     Cancel = True 
     Exit For 
     End If 
    Next 
End Sub 

Непроверенные код (я никогда не могу вспомнить, если это (Row, Col) или (Col, Row)), но я думаю, что будет вам то, что вы после этого. Это отменит сохранение в первой паре, где оба они пусты.

Если это работает, вы можете получить фантазии и выделить заготовки пара (ы), удалить выделение на OK пар (в случае, если они были выделены ранее), обработку по всем парам и удаление Exit For и предоставляя одно сообщение об ошибке, которое необходимо отслеживать.

Мне сказали, что Len(string) = 0 - это более быстрый способ определить, что строка равна нулю, чем string = vbNullString. Никаких гарантий относительно пригодности к цели, но это то, что я узнал.

Answer 3

Попробуйте это:

For i = 4 to 19 
    If ThisWorkbook.Sheets("Planning").Range("A" & i) <> "" AND _ 
     ThisWorkbook.Sheets("Planning").Range("M" & i) <> "" Then 
      MsgBox("Hey bro you didn't wrote properly on line " & i) 
      Cancel = True 

Next i