Преобразование 31-DEC-2016 в 2016-12-31

Question

Я хочу преобразовать 31-DEC-2016, т. Е. Dd-mmm-yyyy в yyyy-mm-dd в XSLT, используя функцию format-dateTime, но выход не так, как ожидалось. Может ли кто-нибудь помочь в этом?

<ns1:QuoteDate> 
      <xsl:value-of select='concat(xp20:format-dateTime(/Quote/QuoteHeader/QuoteDate,"[Y0001]-[M01]-[D01]"),"T00:00:00")'/> 
     </ns1:QuoteDate> 

Я хочу, чтобы получить значение для данного конкретного thing.31-DEC-2016: Это вход и я должен превратить здесь в коде

После того, что превращается, Как Concat значение T00: 00: 00 до даты ??

Answer 1

Вы не можете использовать функцию format-dateTime() для строки, которая недействительна dateTime (или функция format-date() для строки, которая не является допустимой датой). Сначала вам нужно обработать строку, используя строковые функции.

Try:

<xsl:template name="convertDate"> 
    <xsl:param name="datestring"/> 

    <xsl:variable name="d" select="substring-before($datestring, '-')"/> 
    <xsl:variable name="MMM" select="substring-before(substring-after($datestring, '-'), '-')"/> 
    <xsl:variable name="m" select="string-length(substring-before('JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC', $MMM)) div 3 + 1"/> 
    <xsl:variable name="y" select="substring-after(substring-after($datestring, '-'), '-')"/> 

    <xsl:value-of select="$y"/> 
    <xsl:value-of select="format-number($m, '-00')"/> 
    <xsl:value-of select="format-number($d, '-00')"/> 
</xsl:template> 

Вызов этот шаблон с параметром DateString из "31-DEC-2016" будет возвращать значение "2016-12-31".

---

Пример вызова (в основном гадать, не видевший вход):

<ns1:QuoteDate> 
    <xsl:call-template name="convertDate"> 
     <xsl:with-param name="datestring" select="/Quote/QuoteHeader/QuoteDate"/> 
    </xsl:call-template> 
</ns1:QuoteDate> 

---

---

В XSLT 2.0, вы можете определить функцию вместо имени шаблона. Следующая таблица стилей:

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:my="http://www.example.com/my" 
exclude-result-prefixes="xs my"> 
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:function name="my:convertDate"> 
    <xsl:param name="string"/> 
    <xsl:variable name="parts" select="tokenize($string, '-')"/> 
    <xsl:variable name="m" select="index-of (('JAN', 'FEB', 'MAR', 'APR', 'MAY', 'JUN', 'JUL', 'AUG', 'SEP', 'OCT', 'NOV', 'DEC'), $parts[2])"/> 
    <xsl:sequence select="xs:date(concat($parts[3], format-number($m, '-00'), format-number(number($parts[1]), '-00')))" /> 
</xsl:function> 

<xsl:template match="/"> 
    <result> 
     <xsl:value-of select="my:convertDate('9-MAR-2016')"/> 
    </result> 
</xsl:template> 

</xsl:stylesheet> 

вернется:

<?xml version="1.0" encoding="utf-8"?> 
<result>2016-03-09</result> 

Answer 2

Если вы форматированием только даты, я мог бы предложить

формат-дату (дата, формат)

Возможно, это может быть hel р ты,

http://www.sixtree.com.au/articles/2013/formatting-dates-and-times-using-xslt-2.0-and-xpath/