XSLT: общий способ переместить дочерний узел родительского узла в XML

Question

У меня есть эта следующая структура XML:

<root> 
    <p1> 
    <a>1</a> 
    <b>2</b> 
    <_timestamp>20160928201109</_timestamp> 
    <c> 
    <_c_timestamp>20160928201056</_c_timestamp>Tmp</c> 
    </p1> 
    <p2> 
    <a>1</a> 
    <b>2</b> 
    <_timestamp>20160928201109</_timestamp> 
    <d> 
    <_d_timestamp>20160928201056</_d_timestamp>Tmp1</d> 
    </p2> 
</root> 

и хотите преобразовать эту структуру с помощью XSLT:

<root> 
    <p1> 
    <a>1</a> 
    <b>2</b> 
    <_timestamp>20160928201109</_timestamp> 
    <_c_timestamp>20160928201056</_c_timestamp> 
    <c>Tmp</c> 
    </p1> 
    <p2> 
    <a>1</a> 
    <b>2</b> 
    <_timestamp>20160928201109</_timestamp> 
    <_d_timestamp>20160928201056</_d_timestamp> 
    <d>Tmp1</d> 
    </p2> 
</root> 

т.е. любой появление тега со структурой <_anyName_timestamp> должно быть перенесено в родительский узел.

Любые указатели на структуру XSLT были бы полезны.

Answer 1

любое возникновение тега со структурой <_anyName_timestamp> должно быть перемещено к родительскому узлу.

Перемещение - это легкая часть здесь. Трудная часть состоит в том, чтобы идентифицировать элементы для перемещения. Попробуйте:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="*"> 
    <xsl:apply-templates select="*[starts-with(name(), '_') and contains(substring(name(), 2), '_timestamp')]"/> 
    <xsl:copy> 
     <xsl:apply-templates select="node()[not(starts-with(name(), '_') and contains(substring(name(), 2), '_timestamp'))]"/> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet> 

---

Или, возможно, немного более элегантно:

<xsl:template match="*"> 
    <xsl:variable name="ts" select="*[starts-with(name(), '_') and contains(substring(name(), 2), '_timestamp')]" /> 
    <xsl:apply-templates select="$ts"/> 
    <xsl:copy> 
     <xsl:apply-templates select="node()[count(.|$ts) > count($ts)]"/> 
    </xsl:copy> 
</xsl:template>