perl regex сокращать столбцы из файла

Question

У меня есть файл с несколькими строками, содержащими заголовки и значения. Поскольку значения будут вставлены в базу данных, я бы хотел использовать заголовки для обозначения имен столбцов. Таким образом, приведенные ниже данные приведены ниже.

Sales-Date 
Item 
Sale Price 
Discount 
Cost of Item 
Profit (loss) 

Я уже помещал столбцы только в массив и удалял круглые скобки и тире. Это resulst в:

Sales Date 
Item 
Sale Price 
Discount 
Cost of Item 
Profit loss 

Так что мне нужно сделать, это придумать регулярное выражение, которое смотрит на линии, и если его только одно слово, возвращение говорят первые 4 буквы, и если его несколько слов, возвращается первая буква каждого слова. Идеально прописные. Таким образом, желаемые данные будут выглядеть так:

SD 
ITEM 
SP 
DISC 
COI 
PL 

Мне не повезло. Спасибо.

Answer 1

Что-то вроде этого, возможно:

#!/usr/bin/perl 

use strict; 
use warnings; 
use 5.010; 

while (<DATA>) { 
    chomp; 

    # If the line contains whitespace... 
    if (/\s/) { 
    # ... split the line into words ... 
    # ... take the first letter of each word ... 
    # ... join the letters together ... 
    # ... and upper-case the resulting string. 
    say uc join '', map { substr $_, 0, 1 } split /\s+/; 
    } else { 
    # ... otherwise, take the first four characters from the string ... 
    # ... and upper-case them. 
    say uc substr $_, 0, 4; 
    } 
} 

__END__ 
Sales Date 
Item 
Sale Price 
Discount 
Cost of Item 
Profit loss 

Answer 2

Возможное решение состоит в том, чтобы разделить линию на массив по пробелу, а не просто захватить каждую букву каждого слова. Что-то вроде:

my $line = "Sales Date"; 

# Split line into an array separated by whitespace 
my @words = split /\s+/, $line; 

my $letters; 
# For loop through number of words in array 
for (@words) { 
    m/(.)/; 
    $letters .= $1; 
} 

print $letters; 

Вышеупомянутое напечатает SD. Вы можете просто изменить m/(.) /, Чтобы представить количество символов, которые вы хотите захватить.

Answer 3

my @arr = map { 
    # make entire string upper case 
    local $_ = uc; 
    # remove trailing white-spaces (sometimes chomp fails on line endings) 
    s/\s+\z//; 

    # more words? 
    /\s/ 
     # take first letter of every word 
     ? join("", /\b(\w)/g) 
     # take first 1 to 4 letters (and be greedy at that) 
     : /(\w{1,4})/; 
} 
<DATA>; 

print $_, "\n" for @arr; 

__DATA__ 
Sales Date 
Item 
Sale Price 
Discount 
Cost of Item 
Profit loss 

выход

SD 
ITEM 
SP 
DISC 
COI 
PL