Использование VBA-Excel для SQL запроса по нескольким базам данных

Question

Использование Excel 2010, SQL и DAO

Я пытаюсь выполнить запрос к таблицам, которые проживают за пределами текущей таблицы. Это было бы тривиально, внутри Access, со связанными таблицами/базами данных, но, используя VBA в excel, меня заглушат.

Предположив это:

ExcelFileOne; Tab; various headed field/columns 
ExcelFileTwo; Tab; various headed field/columns 

Я хочу, чтобы выполнить запрос внутри третьего файла Excel, который выходит что-то вроде этого [используя точечную нотацию для объяснения, а не кодирования ....] - простой пример :

SELECT FileOne.[Tab$].Fields, FileTwo.[Tab$].Fields, etc. 
    FROM FileOne, FileTwo, Thisworkbook 
    WHERE (FileOne.[Tab$].field2 <> FileTwo.[Tab$].Field2) 
     AND (ThisWorkbook.[Tab$].Field1 ....) 

В принципе, я хочу дублировать то, что Access будет делать изначально, для этого связанного файла.

Указатели в правильном направлении?

[[Я мог бы использовать указатель на то, почему использование «Excel 8.0 ...» в соединении работает или выходит из строя на Excel2010, с файлами макросов и как загрузить вариант 12 или 14 в сети/системе, закрытой для пользователи ....]]

Answer 1

Вы действительно можете запросить другие книги, используя DAO и ADO, непосредственно в SQL-запросе, а также запросить таблицы баз данных Access, просто ссылаясь на их пути. И наоборот, в запросе Access вы можете запросить книги Excel! Это свидетельствует о том, что Jet/ACE SQL engine (файлы Windows .dll) не ограничивается каким-либо одним продуктом MS Office или программой Windows, а инструментом для всех.

В обоих примерах макросы делают прямое подключение к первой книге, а в SQL-запросе каждый косвенно подключается ко второй книге. Вы можете запускать код внутри или снаружи книг. Также оба запускают genric INNER JOIN на FileOne и Рабочие листы FileTwo, но любой совместимый оператор Jet/ACE SQL должен работать. И оба выходных запроса возвращаются в ранее существовавшие РЕЗУЛЬТАТЫ.

DAO

Dim dbE As Object, db As Object, rst As Object 
Dim sqlString As String 
Dim i As Integer 
Const dbOpenDynaset = 2, dbReadOnly = 4 

' OPEN DB CONNECTION 
Set dbE = CreateObject("DAO.DBEngine.120") 'ALSO TRY: DAO.DBEngine.35 OR .36 
Set db = dbE.OpenDatabase("C:\Path\To\FileOne.xlsm", False, True, "Excel 12.0 Xml;HDR=Yes") 

' OPEN QUERY RECORDSET 
sqlString = " SELECT * FROM [TAB$] t1" _ 
       & " INNER JOIN (SELECT * FROM" _ 
       & " [Excel 12.0 Xml;HDR=Yes;Database=C:\Path\To\FileTwo.xlsm].[TAB$]) t2" _ 
       & " ON t1.ID = t2.ID" 

Set rst = db.OpenRecordset(sqlString, dbOpenDynaset, dbReadOnly) 

' COLUMNS 
For i = 1 To rst.Fields.Count 
    Worksheets("RESULTS").Cells(1, i) = rst.Fields(i - 1).Name 
Next i 

' DATA ROWS 
Worksheets("RESULTS").Range("A2").CopyFromRecordset rst 

rst.Close 
db.Close 

Set rst = Nothing 
Set db = Nothing 
Set dbE = Nothing 

АДО

Dim conn As Object, rst As Object, fld As Object 
Dim strConnection As String, strSQL As String 
Dim i As Integer 

Set conn = CreateObject("ADODB.Connection") 
Set rst = CreateObject("ADODB.Recordset") 

' OPEN DB CONNECTION 
strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" _ 
        & "Data Source='C:\Path\To\FileOne.xlsm';" _ 
        & "Extended Properties=""Excel 12.0 Xml;HDR=YES;"";"   

conn.Open strConnection 

' OPEN QUERY RECORDSET 
strSQL = " SELECT * FROM [TAB$] t1" _ 
      & " INNER JOIN (SELECT * FROM" _ 
      & " [Excel 12.0 Xml;HDR=Yes;Database=C:\Path\To\FileTwo.xlsm].[TAB$]) t2" _ 
      & " ON t1.ID = t2.ID" 

rst.Open strSQL, conn 

' COLUMNS 
For i = 1 To rst.Fields.Count 
    Worksheets("RESULTS").Cells(1, i) = rst.Fields(i - 1).Name 
Next i 

' DATA ROWS 
Worksheets("RESULTS").Range("A2").CopyFromRecordset rst 

rst.Close 
conn.Close 

Set rst = Nothing 
Set conn = Nothing