Как инициализировать параметр вар Record

Question

У меня есть тип записи:

type 
    TIPInfo = record 
    IP, 
    HostName, 
    City, 
    Region, 
    Country, 
    Loc, 
    Org: WideString 
    end; 

Функция вернуть записи данных:

function GetPublicIPInfo(var IPInfo: TIPInfo): Boolean; 
begin 
    // initialize 
    FillChar(IPInfo, SizeOf(TIPInfo), 0); 

    // populate data 
    IPInfo.IP := GetVallue('ip'); 
    IPInfo.HostName := GetVallue('hostname'); 
    IPInfo.City := GetVallue('city'); 
    // etc... 

    Result := IsOk; 
end; 

Вызывающий:

var 
    IPInfo: TIPInfo; 

if GetPublicIPInfo(IPInfo) then... // use data 

ли это правильно способ инициализировать var TIPInfo, вызвав FillChar, или я должен установить каждое поле в пустую строку? Должен ли вызывающий абонент сделать это?

Кроме того, было бы лучше использовать параметр out в случае (поскольку функция не считывает данные)?

Answer 1

Использование только FillChar здесь неправильное. Если какой-либо из членов WideString не пуст, вы пронесете их таким образом. Вместо этого я предлагаю следующее:

Finalize(IPInfo); 
FillChar(IPInfo, SizeOf(TIPInfo), 0); 

Или другой способ, чтобы определить запись по умолчанию, как типизированный константа:

const 
    DefaultIPInfo: TIPInfo =(); 

Затем вы можете использовать простое задание:

IPInfo := DefaultIPInfo; 

В современной версии Delphi вы можете использовать этот гораздо более читаемый код:

IPInfo := Default(TIPInfo); 

Более подробно об этой конкретной теме, обратитесь к следующим темам:

• Delphi "default" keyword with Record types in older Delphi versions.
• How to properly free records that contain various types in Delphi at once?

Обратите внимание, что утечка в вашем коде трудно найти, потому что WideString переменные реализованы в виде COM BSTR объектов, и выделяется на COM куче. Поэтому, если вы используете обнаружение утечки памяти для менеджера памяти Delphi, утечка не будет обнаружена, потому что она просочилась из другой кучи.

В вашем случае, поскольку ваша запись является управляемым типом и содержит только управляемые типы, вы можете использовать параметр out для хорошего эффекта. Для управляемых типов, out параметры означают, что компилятор будет генерировать код, на месте вызова, по умолчанию инициализировать запись перед передачей его в

Рассмотрим следующую программу:.

{$APPTYPE CONSOLE} 

type 
    TRec = record 
    Value: WideString; 
    end; 

procedure Foo1(var rec: TRec); 
begin 
end; 

procedure Foo2(out rec: TRec); 
begin 
end; 

procedure Main; 
var 
    rec: TRec; 
begin 
    rec.Value := 'Foo'; 
    Foo1(rec); 
    Writeln(rec.Value); 
    Foo2(rec); 
    Writeln(rec.Value); 
end; 

begin 
    Main; 
end. 

Выход:

 
Foo 

Если ваша запись содержит сочетание управляемых и неуправляемых типов, то ситуация не так хороша.

{$APPTYPE CONSOLE} 

type 
    TRec = record 
    Value1: WideString; 
    Value2: Integer; 
    end; 

procedure Foo1(var rec: TRec); 
begin 
end; 

procedure Foo2(out rec: TRec); 
begin 
end; 

procedure Main; 
var 
    rec: TRec; 
begin 
    rec.Value1 := 'Foo'; 
    rec.Value2 := 42; 
    Foo1(rec); 
    Writeln(rec.Value1); 
    Writeln(rec.Value2); 
    Foo2(rec); 
    Writeln(rec.Value1); 
    Writeln(rec.Value2); 
end; 

begin 
    Main; 
end. 

Выход:

 
Foo 
42 

42 

только управляемые члены по умолчанию инициализируется для out параметров. Поэтому ваш лучший выбор - это инициализировать переменную самостоятельно, даже если она передается как параметр out.

Подробнее о out параметрах можно найти здесь: What's the difference between "var" and "out" parameters?