Преобразование файлов Excel в текст с помощью Access VBA

Question

Я пытаюсь сохранить каждый .xls-файл в папке в виде текста, используя Access VBA. Я закрепил код ниже. Тем не менее, он только успешно сохраняет 1-й файл excel в виде текста, а затем он, кажется, виснет.

Я рассмотрел это сообщение, которое, как я думаю, достигает чего-то похожего на то, что я хочу: HERE. Но я был так долго, что ничего не имеет смысла! Есть идеи? Он застревает на ActiveWorkbook.Close?

Public Sub FormatAsText() 
Dim myfile As String 
Dim xlApp As Excel.Application 
Dim xlWB1 As Excel.Workbook 

Dim objFso As FileSystemObject 
Dim strPath As String 
Dim objFolder As Folder 
Dim objFile As File 

     Set xlApp = New Excel.Application 
     strPath = "C:FolderLocation..." 

     Set objFso = CreateObject("Scripting.FileSystemObject") 
     Set objFolder = objFso.GetFolder(strPath) 

     myfile = Dir(strPath & "\*.xls") 

      For Each objFile In objFolder.Files 
       If objFile.Name Like "*.xls" Then 
        Workbooks.Open objFile, ReadOnly:=False 
        ActiveWorkbook.SaveAs FileName:=strPath & "\" & Replace(myfile, ".xls", ".txt"), FileFormat:=xlTextWindows 
        ActiveWorkbook.Close 
       End If 
      Next objFile 

     Debug.Print myfile 

Set xlApp = Nothing 
Set xlWB1 = Nothing 

Set objFso = Nothing 

Set objFolder = Nothing 
Set objFile = Nothing 

End Sub 

Answer 1

Добавляя xlApp.Visible = True после Set xlApp = New Excel.Application вы обнаружили, Excel ждет вас, чтобы сказать ему, нужно ли перезаписывать существующий файл, который имеет такое же имя, как и тот, который вы пытаетесь сохранить.

Это происходит потому, что вы присвоить значение MYFILE только один раз ...

myfile = Dir(strPath & "\*.xls") 

... но затем повторно использовать то же имя в качестве основы для генерации имени каждого .txt файл, который вы пытаетесь сохранить ...

FileName:=strPath & "\" & Replace(myfile, ".xls", ".txt") 

Я думаю, что вы можете просто заменить objFile.Name, потому что он должен совпадать с именем текущего файла рабочей книги ... что означает, что ваше имя файла .txt будет отличаться каждый раз через цикл For Each.

FileName:=strPath & "\" & Replace(objFile.Name, ".xls", ".txt")