Inno Setup - Как локализовать имена компонентов и типов?

Question

Как локализовать имена компонентов и типов? Например:

[Languages] 
Name: "eng"; MessagesFile: "Idiomas\English.isl" 
Name: "spa"; MessagesFile: "Idiomas\Spanish.isl" 

Если я выбираю английский язык:

[Types] 
Name: "full"; Description: "Full installation" 
Name: "compact"; Description: "Compact installation" 
Name: "custom"; Description: "Custom installation"; Flags: iscustom 

[Components] 
Name: "program"; Description: "Program Files"; Types: full compact custom; Flags: fixed 
Name: "readme"; Description: "Readme File"; Types: full 

или если я выбираю испанский:

[Types] 
Name: "full"; Description: "Instalación Completa" 
Name: "compact"; Description: "Instalación Mínima" 
Name: "custom"; Description: "Instalación Personalizada"; Flags: iscustom 

[Components] 
Name: "program"; Description: "Archivos de Programa"; Types: full compact custom; Flags: fixed 
Name: "readme"; Description: "Archivo de Ayuda"; Types: full 

Answer 1

Определение custom messages в языковых файлах:

• idiomas\English.isl :

  [CustomMessages] 
  FullInstallation=Full installation 
  CompactInstallation=Compact installation 
  CustomInstallation=Custom installation 
  ProgramFilesComponent=Program Files 
  ReadmeFileComponent=Readme File 
  

• idiomas\Spanish.isl:

  [CustomMessages] 
  FullInstallation=Instalación Completa 
  CompactInstallation=Instalación Mínima 
  CustomInstallation=Instalación Personalizada 
  ProgramFilesComponent=Archivos de Programa 
  ReadmeFileComponent=Archivo de Ayuda 
  

• или вы можете использовать раздел [CustomMessages] в главном .ISS файле:

  [CustomMessages] 
  eng.FullInstallation=Full installation 
  spa.FullInstallation=Instalación Completa 
  ... 
  

И затем использовать эти пользовательские сообщения используя {cm:MessageName} constant в сценарии:

[Types] 
Name: "full"; Description: "{cm:FullInstallation}" 
Name: "compact"; Description: "{cm:CompactInstallation}" 
Name: "custom"; Description: "{cm:CustomInstallation}"; Flags: iscustom 

[Components] 
Name: "program"; Description: "{cm:ProgramFilesComponent}"; Types: full compact custom; Flags: fixed 
Name: "readme"; Description: "{cm:ReadmeFileComponent}"; Types: full