Имя подзапроса SPARQL

Question

У меня есть следующий запрос SPARQL, содержащий подвыбор. Данные содержат несколько графиков, и я хочу знать, что график значение для ?b и ?m приходит из:

select ?b, ?m, ?g1 
where { 

{ 
    select ?o1, ?o2, ?e 
    where{ 
     graph ?g{ 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_infector_pid> ?o1. 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_infectee_pid> ?o2. 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_iteration> '0'^^xsd:decimal. 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_exposureday> ?e. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_pid1> ?o1. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_pid2> ?o2. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_acttype1> '5'^^xsd:decimal. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_acttype2> '5'^^xsd:decimal 
    } 
    }ORDER BY ASC(?e) LIMIT 1 
} 

{ 

graph ?g1 { 
?b <http://ndssl.bi.vt.edu/chicago/vocab/getInfectedBy> ?o1. 
?m <http://ndssl.bi.vt.edu/chicago/vocab/getInfectedBy>* ?b. 
    } 

} 

} 

второй шаблон графа содержит переходный путь свойства и запрос обеспечивает следующие правильный результат:

b              m              g1 
----------------------------------------------------- ----------------------------------------------------- ------------------------------------------------------- 
<http://ndssl.bi.vt.edu/chicago/person/pid#446734805> <http://ndssl.bi.vt.edu/chicago/person/pid#446753456> <http://ndssl.bi.vt.edu/chicago/dendrogram/replicate1/> 

Однако я хочу видеть промежуточные узлы и подсчитывать длину пути от транзитивных отношений. Если удалить graph ?g1 из запроса, то он показывает информацию промежуточного узла, как следующее:

b              m 
--------------------------------------------------- --------------------------------------------------- 
http://ndssl.bi.vt.edu/chicago/person/pid#446718746 http://ndssl.bi.vt.edu/chicago/person/pid#446718746 
http://ndssl.bi.vt.edu/chicago/person/pid#446734805 http://ndssl.bi.vt.edu/chicago/person/pid#446734805 
http://ndssl.bi.vt.edu/chicago/person/pid#446734805 http://ndssl.bi.vt.edu/chicago/person/pid#446753456 

Цель запроса, чтобы выяснить имя графа для согласования ?b и ?m. Следовательно, я хочу использовать graph ?g1. Можно ли показывать промежуточные узлы, сохраняя ключевое слово ? Я использую Virtuoso.

Answer 1

Поскольку вы не используете g, заявление GRAPH не требуется. Обратите также внимание, что второй оператор GRAPH использует только ?o1, поэтому следующий запрос выполняет то, что вы хотите. Вы также можете проверить SPARQL syntax в своем предложении select.

PREFIX ndssl: <http://ndssl.bi.vt.edu/chicago/vocab/> 
SELECT ?b ?m ?g1 
WHERE { 
    { 
    SELECT ?o1 
    WHERE { 
     ?s ndssl:dendrogram_infector_pid ?o1    . 
     ?s ndssl:dendrogram_infectee_pid ?o2    . 
     ?s ndssl:dendrogram_iteration  '0'^^xsd:decimal . 
     ?s ndssl:dendrogram_exposureday ?e    . 
     ?s1 ndssl:contactnetwork_pid1  ?o1    . 
     ?s1 ndssl:contactnetwork_pid2  ?o2    . 
     ?s1 ndssl:contactnetwork_acttype1 '5'^^xsd:decimal . 
     ?s1 ndssl:contactnetwork_acttype2 '5'^^xsd:decimal 
    } ORDER BY ASC(?e) LIMIT 1 
    } 
    GRAPH ?g1 { 
    ?b ndssl:getInfectedBy ?o1 . 
    ?m ndssl:getInfectedBy* ?b . 
    } 
} 

В конечной точке при условии не подходит для ?b или ?m, независимо от того, используется ли GRAPH заявление или нет.