Как сравнить шаблоны URL в XSLT?

Question

Я использую XSLT для преобразования моего XML в модифицированный XML. Я хочу проверить условие: где заголовок указывает на конечную точку, отличную от pdf, что-то делать. Ниже приведен мой XML:

<vce> 
    <form> 
     <headlineURL> 
      <a href="http://www.example.com/bin/internal-application.pdf" /> 
     </headlineURL> 
    </form> 
    <form> 
     <headlineURL> 
      <a href="http://www.demo.com" /> 
     </headlineURL> 
    </form> 
    <form> 
     <headlineURL> 
      <a href="http://www.demo-live.in" /> 
     </headlineURL> 
    </form> 
</vce> 

Что я должен указывать в условии when в XSLT? Я хочу, чтобы запустить состояние, при котором headlineURL содержит не Pdf конечной точки (например, «http://www.demo.com», «» http://www.demo-live.in «)

<xsl:choose> 
    <xsl:when test= ...> 
    <!-- Do something --> 
    </xsl:when> 
</xsl:choose> 

Любая помощь ценится

Answer 1

Следующая XSLT-1.0 код проверяет наличие если входы headlineURL/a/@href s кончаются строкой .pdf. проверка чувствителен к регистру и проверяет только .pdf и не.PDF, поэтому я бы рекомендовал добавить прецедентное нейтрализацию-шаблон до проверки в случае необходимости.

<?xml version="1.0" ?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" />    <!-- output data as XML --> 
    <xsl:strip-space elements="*" />   <!-- remove unnecessary spaces in output --> 

    <xsl:template match="/vce/form/headlineURL"> 
    <xsl:variable name="doExec">    <!-- set variable with predicate --> 
     <xsl:call-template name="ends-with"> <!-- check if input ends-with '.pdf' --> 
     <xsl:with-param name="txt" select="a/@href" /> 
     <xsl:with-param name="ends" select="'.pdf'" /> 
     </xsl:call-template> 
    </xsl:variable> 
    <xsl:if test="$doExec != 'true'"> 
     <xsl:value-of select="a/@href" />: No PDF!!!  <!-- replace this line with the desired output --> 
    </xsl:if> 
    </xsl:template> 

    <!-- XSLT 1.0 version of the function 'ends-with' --> 
    <xsl:template name="ends-with"> 
    <xsl:param name="txt" /> 
    <xsl:param name="ends" /> 
    <xsl:value-of select="substring($txt, string-length($txt) - string-length($ends) +1) = $ends" /> 
    </xsl:template> 

</xsl:stylesheet>