Прыжки назад 1000 строк

Question

Я пытался сделать код, который, когда вы в самом конце, попросит вас, хотите ли вы попробовать еще раз. Если вы нажмете «y», тогда он вернется на 1000 строк, прямо в начале программы.

Ну, очевидно, это не сработало, так как я получил ошибку «прыгать относительно вне диапазона». Так что я сделал подскакивает каждые 50 строк, имеющих в общей сложности 20 прыжков, как

start: 
. 
s20: jmp start 
. 
. 
. 
s2: jmp s3 
. 
s1: jmp s2 
. 
jmp s1 

Теперь после того, как сделать это, я запустил программу, и когда я нажал «у», TASM вид замерзала. Он просто показывал последний экран с входом «y» и миганием _. Я больше не мог нажимать персонажа.

Спасибо.

Answer 1

В x86 вам не нужна каскадная последовательность прыжков, так как jmp может перепрыгнуть через весь сегмент. Просто условный прыжок, такой как jne, имеет ограниченный диапазон. Таким образом, вы можете изменить errorneous условный переход к комбинации безусловного близкого перехода и условного короткого прыжка:

В качестве примера, изменение

.MODEL small 
.STACK 1000h 

.CODE 
main: 

top: 
    mov ax, 1 
    jmp bottom 


ORG 1000h    ; A big block between top and bottom 

bottom: 
    cmp ax, 0 

    je top    ; **Error** Relative jump out of range by 0F85h bytes 

    mov ax, 4C00h  ; Return 0 
    int 21h 

END main 

в

.MODEL small 
.STACK 1000h 

.CODE 
main: 

top: 
    mov ax, 1 
    jmp bottom 


ORG 1000h    ; A big block between top and bottom 

bottom: 
    cmp ax, 0 

    jne skip   ; Short conditional jump 
    jmp top    ; Near unconditional jump 
    skip: 

    mov ax, 4C00h  ; Return 0 
    int 21h 

END main 

TASM может сделать автоматически для вас. Разместить запрос «ПЕРЕХОД» в начале (или там, где вам это нужно) файл:

JUMPS 

.MODEL small 
.STACK 1000h 

.CODE 
main: 

top: 
    mov ax, 1 
    jmp bottom 


ORG 1000h    ; A big block between top and bottom 

bottom: 
    cmp ax, 0 

    je top    ; TASM will change this line to a JNE-JMP combination 

    mov ax, 4C00h  ; Return 0 
    int 21h 

END main 

Набор 80386 инструкции (ISA) имеет инструкцию для почти условного перехода. Если ваш эмулятор поддерживает ISA 80386 (DOSBox делает), вы можете сказать TASM использовать его. Вставьте директиву .386:

.MODEL small 
.386     ; Use 80386 instruction set 
.STACK 1000h 

.CODE 
main: 

top: 
    mov ax, 1 
    jmp bottom 


ORG 1000h    ; A huge block between top and bottom 

bottom: 
    cmp ax, 0 

    je top    ; Correct jump because of '.386' 

    mov ax, 4C00h  ; Return 0 
    int 21h 

END main