Moo (se), before и inheritance

Question

У меня есть класс Moo (se) [0] с рядом методов, которые имеют один и тот же тип «инструкции охраны» вверху. Вместо того, чтобы писать один и тот же код несколько раз, я решил, что могу поставить заявление в модификатор метода «до», и это работает отлично. Если этот класс не является подклассом, потому что тогда «перед защитой» никогда не вызывается.

package Foo; 
use feature 'say'; 
use Moose; 

has '_init' => (
    is  => 'rw', 
    isa  => 'Bool', 
    default => 0 
); 

sub init { 
    shift->_init(1); 
} 

sub method { 
    say "in Foo::method"; 
} 

before method => sub { 
    my $self = shift; 
    warn "==> Foo is not initialized\n" unless $self->_init; 
}; 


package Bar; 
use feature 'say'; 
use Moose; 
extends 'Foo'; 

sub method { 
    say "in Bar::method"; 
} 


package main; 
use feature 'say'; 

my $foo = Foo->new; 
say "foo the wrong way:"; 
$foo->method; 

say "foo the right way:"; 
$foo->init; 
$foo->method; 

my $bar = Bar->new; 
say "bar the wrong way:"; 
$bar->method; 

Выход затем (с некоторыми добавлениями новых линий):

foo the wrong way: 
==> Foo is not initialized 
in Foo::method 

foo the right way: 
in Foo::method 

bar the wrong way: 
in Bar::method 

Я предполагаю, что это поведение является, но есть ли (хороший) способ убедиться, что все подклассы также наследуют " перед "инструкцией модификатора метода/охраны? Или есть другой способ сделать это (я подозреваю, что это довольно распространенная конструкция). Обратите внимание, что исключение будет выведено в операторе real guard, но «предупреждение» намного проще в примере кода.

[0] Я предпочитаю использовать Moo, потому что я не использую никаких функций, требующих MOP, но оба Moo и Moose работают точно так же в этом вопросе.

Редактировать Использование ролей.

Если вы добавили Role для этого (как предложено tobyink), и добавьте еще один способ сделать вещи немного более «реальной жизнью», я получаю своеобразный результат.

package Warning::NotInit; 
use feature 'say'; 
use Moose::Role; 

has '_init' => (is => 'rw', isa => 'Bool', default => 0); 

before qw/ m1 m2/=> sub { 
    my $self = shift; 
    my $class = ref($self); 
    warn "==> $class is not initialized\n" unless $self->_init; 
}; 

package Foo; 
use feature 'say'; 
use Moose; 
with 'Warning::NotInit'; 

sub init { shift->_init(1) } 
sub m1 { say "in Foo::m1" } 
sub m2 { say "in Foo::m2" } 

package Bar; 
use feature 'say'; 
use Moose; 
extends 'Foo'; 
with 'Warning::NotInit'; 

sub m1 { say "in Bar::m1" } 


package main; 
use feature 'say'; 

При вызове не перекрытый метод в подклассе метод before называется дважды.

my $bar = Bar->new; 
say "bar the wrong way:"; 
$bar->m1; 
$bar->m2; 

Выход:

bar the wrong way: 
==> Bar is not initialized 
in Bar::m1 

==> Bar is not initialized 
==> Bar is not initialized 
in Foo::m2 

Почему она называется дважды?

Answer 1

Да, это не так, как работают модификаторы метода. Модификатор before будет часть метод сам. Когда вы переопределяете метод в вашем подклассе, вы переопределяете все поведение суперкласса, то есть вы также переопределяете модификатор метода.

Вы могли бы решить эту проблему путем факторизации метода модификатора в роли, которая может быть применена к каждому классу, как это:

package Warning::NotInit; 
use feature 'say'; 
use Moose::Role; 

has '_init' => (
    is  => 'rw', 
    isa  => 'Bool', 
    default => 0 
); 

before method => sub { 
    my $self = shift; 
    my $class = ref($self); 
    warn "==> $class is not initialized\n" unless $self->_init; 
}; 

package Foo; 
use feature 'say'; 
use Moose; 
with 'Warning::NotInit'; 

sub init { 
    shift->_init(1); 
} 

sub method { 
    say "in Foo::method"; 
} 

package Bar; 
use feature 'say'; 
use Moose; 
extends 'Foo'; 
with 'Warning::NotInit'; 

sub method { 
    say "in Bar::method"; 
} 


package main; 
use feature 'say'; 

my $foo = Foo->new; 
say "foo the wrong way:"; 
$foo->method; 

say "foo the right way:"; 
$foo->init; 
$foo->method; 

my $bar = Bar->new; 
say "bar the wrong way:"; 
$bar->method;