Удалить всю строку на основе соответствия?

Question

Необходимо удалить несколько строк в CSV-файле в Excel на основе соответствия в столбце L на листе 1 со столбцом A на листе2. Содержимое - это адреса электронной почты. Как я могу это достичь?

Итак, если столбец sheet2 имеет адрес электронной почты, который соответствует любому из адресов электронной почты в sheet1 - столбец L, то он должен удалить всю строку из листа 1, где находится этот адрес электронной почты.

Лист1 ниже:

Sheet2 ниже:

@mehow, вот образ, который я получаю, когда я запустить свой код в качестве модуля:

Answer 1

Это будет работать, очень быстро для того, что вы хотите сделать, поскольку оно не включает ЛЮБЫЕ циклы.

Sub DeleteDuplicates() 

Dim StartingScreenUpdateValue As Boolean 
Dim StartingEventsValue As Boolean 
Dim StartingCalculations As XlCalculation 

With Application 
    StartingScreenUpdateValue = .ScreenUpdating 
    StartingEventsValue = .EnableEvents 
    StartingCalculations = .Calculation 
    .ScreenUpdating = False 
    .EnableEvents = False 
    .Calculation = xlCalculationManual 
End With 


Dim varTestValues As Variant 
Dim sh1 As Worksheet 
Dim sh2 As Worksheet 

Set sh1 = Sheets("Sheet1") 
Set sh2 = Sheets("Sheet2") 

With sh2 
    varTestValues = .Range("A1", .Range("A" & .Rows.Count).End(xlUp)) 
End With 

sh1.Range("L1", sh1.Range("L" & sh1.Rows.Count).End(xlUp)) _ 
    .AutoFilter Field:=12, Criteria1:=Application.Transpose(varTestValues), Operator:=xlFilterValues 

sh1.Range("L2", sh1.Range("L" & sh1.Rows.Count).End(xlUp)) _ 
    .SpecialCells(xlCellTypeVisible).EntireRow.Delete 

sh1.AutoFilterMode = False 

With Application 
    .ScreenUpdating = StartingScreenUpdateValue 
    .EnableEvents = StartingEventsValue 
    .Calculation = StartingCalculations 
End With 

End Sub 

Примечание: Этот код выполняется при условии, ваши данные заголовки, если он не пожалуйста, сообщите.

ПОМНИТЕ Всегда запускать любой код на копии ваших данных, а не фактические данные, пока вы не уверены в том, что он работает на 100%.