Как ссылаться на объект в анонимной подсистеме при вызове конструктора?

Question

$mech = new WWW::Mechanize(
    onerror => sub { 
     say "Failed to get " . $mech->uri . ". Retrying."; 
     $mech->get($mech->uri); 
    } 
); 

Как я могу заставить вышеуказанный код работать? Я хочу обратиться к URI, что объект Mechanize просто попытался получить, а затем повторить попытку, но я не могу понять, как ссылаться на это внутри вызова конструктора.

Answer 1

Это неправильный способ решить эту проблему. WWW::Mechanize хочет здесь croak-совместимую функцию, чтобы иметь возможность выйти из фатальной ошибки. Он будет передавать список строк, а объект $mech не будет виден - и не обязательно будет действительным.

Если вы хотите повторить запросы, поместите эту логику вокруг запросов с помощью блока try. Если вы хотите обобщить это на все запросы, подкласс WWWM.

Answer 2

Существует много других условий помимо отказавшего запроса, который может вызвать ваш обработчик onerror; в этих случаях нет смысла отправлять новый запрос.

Вы должны поймать исключения, выброшенные $mech->get, и повторно выбросить любые ошибки, которые не являются ошибками соединения. Вы можете сделать это в подпрограмме:

use strict; 
use warnings 'all'; 
use 5.010; 

use Try::Tiny; 
use WWW::Mechanize; 

sub retry { 
    my ($mech, $uri, $options) = @_; 

    $options //= {}; 

    my $method = $options->{method} // 'get'; 
    my $retries = $options->{retries} // 3; 
    my $interval = $options->{interval} // 3; 

    _try_request($mech, $uri, $method); 

    while (! $mech->success && $retries-- > 0) { 
     warn "Failed " . uc($method) . "ing $uri. Re-trying ...\n"; 
     sleep $interval; 

     _try_request($mech, $uri, $method); 
    } 
} 

sub _try_request { 
    my ($mech, $uri, $method) = @_; 

    try { 
     $mech->$method($uri); 
    } 
    catch { 
     die $_ unless /Can't connect/; # re-throw other errors 
    }; 
} 

my $mech = WWW::Mechanize->new; 
retry($mech, 'http://www.stackoverflow.comx', { retries => 1 }); 

Выход:

Failed GETing http://www.stackoverflow.comx. Re-trying ... 

В качестве альтернативы, вы можете создать подкласс WWW :: Mechanize и переопределить методы запроса. Это избавит вас от необходимости обходить объект $mech.