Попытка соединения таблицы между БД доступа с использованием VBA. Получение ISAM не найдена ошибка

Question

У меня есть разделенная база данных, где и передняя, ​​и задняя часть - файлы accdb. Поскольку одна из моих таблиц использует свойство AppendOnly = Yes, я не могу использовать диспетчер таблицы ссылок или свойство refreshlink при перемещении бэкэнд. Бэкэнд время от времени движется, потому что мой ИТ любит перестраивать серверы.

Итак, мое решение состоит в том, чтобы написать функцию, которая запрашивает адресное пространство, удаляет все связанные в настоящее время таблицы, а затем перебирает все бэкэнд-таблицы и связывает их с интерфейсом. На этой последней части я получаю ошибку времени выполнения 3170, которая не может найти подходящий ISAM. Я не знаю почему.

код ниже:

Public Function MoveDB() 

'this function will replace the linked table manager. It will open a file select dialog box to allow the user to pick the new location of the DB backend. 
'It will then break all the current links and then recreate them. We need to do this vice use the relink function because the cases table uses AutoAppend which stores old path data 
' and breaks the relink function which is why linked table manager does not work. 

' FileDialog Requires a reference to Microsoft Office 11.0 Object Library. 

'variables to get the database path 
Dim fDialog As Office.FileDialog 
Dim varFile As Variant 
Dim DriveLetter As String 
Dim NetworkPath As String 
Dim DrivePath As String 
Dim SubPath As String 


'variables to link the database 
Dim db As DAO.Database 
Dim BEdb As DAO.Database 
Dim oldtdf As DAO.TableDef 
Dim tblName As String 
Dim newtdf As DAO.TableDef 
Dim BEtdf As DAO.TableDef 


Set db = CurrentDb() 

' Set up the File Dialog. 
Set fDialog = Application.FileDialog(msoFileDialogFilePicker) 
With fDialog 

    ' Do not Allow user to make multiple selections in dialog box 
    .AllowMultiSelect = False 

    'set the default folder that is opened 
    .InitialFileName = CurrentProject.Path & "\BE" 

    ' Set the title of the dialog box. 
    .Title = "Please select the Database Backend" 

    ' Clear out the current filters, and add our own. 
    .Filters.Clear 
    .Filters.Add "Access Databases", "*.accdb" 

    ' Show the dialog box. If the .Show method returns True, the 
    ' user picked a file. If the .Show method returns 
    ' False, the user clicked Cancel. 
    If .Show = True Then 

'We need to determine the full network path (including server name) to the DB backend. The reason is that different users may have the share drive mapped with different letters. 
'If the backend is mapped using the drive letter of the user moving the DB then other users may not have a valid path. The full network path is universal 


'Get the mapped drive letter from the path of the selected DB file 
    DriveLetter = Left$(Trim(fDialog.SelectedItems(1)), 2) 
'Get the path of the selected DB file minus the drive letter 
    SubPath = Mid$(Trim(fDialog.SelectedItems(1)), 3) 
'Get the full network path of the mapped drive letter 
    DrivePath = GETNETWORKPATH(DriveLetter) 
'Combine the drive path and the sub path to get the full path to the selected DB file 
    NetworkPath = DrivePath & SubPath 
    'MsgBox (NetworkPath) 
    Else 
    MsgBox "You clicked Cancel in the file dialog box." 
    End If 
End With 
    'Now we need to delete all the linked tables 

For Each oldtdf In db.TableDefs 
    With oldtdf 
     If oldtdf.Attributes And dbAttachedODBC Or oldtdf.Attributes And dbAttachedTable Then 
     'this is a linked table 
      tblName = .Name 
      DoCmd.DeleteObject acTable, tblName 
     End If 
    End With 
Next oldtdf 
tblName = "" 


'Now we link all the tables from the backend to the front end 
Set BEdb = OpenDatabase(NetworkPath) 
For Each BEtdf In BEdb.TableDefs 
    tblName = BEtdf.Name 
    If Left(tblName, 4) <> "~TMP" Then 
     Set newtdf = db.CreateTableDef(strTable) 
     newtdf.Connect = "Database = " & NetworkPath 
     newtdf.SourceTableName = tblName 
     newtdf.Name = tblName 
    db.TableDefs.Append newtdf 
    End If 
Next BEtdf 

End Function 

Ошибка возникает на линии

db.TableDefs.Append newtdf 

. Я ищу либо для того, чтобы этот код работал, либо как путь вокруг известной ошибки, которая предотвращает обновление ссылок при использовании свойства AppendOnly=Yes.

Заранее благодарим за любую помощь.

Answer 1

Я думаю, вы просто отсутствует точка с запятой на вашей строке и удалить лишние пробелы

newtdf.Connect = ";Database=" & NetworkPath 

Answer 2

В качестве альтернативы, вы можете использовать DoCmd.TransferDatabase метод и не забудьте оставить из таблицы MSys, поскольку они не имеют никакого прямого использования приложения между разрезание файлов:

If Left(tblName, 4) <> "~TMP" And Left(tblName, 4) <> "MSys" Then 
    DoCmd.TransferDatabase acLink, "Microsoft Access", NetworkPath, _ 
          acTable, tblName, tblName, False 
End If