Excel VBA Удаление символов Unicode в строке

Question

Как удалить все специальные символы, которые не подпадают под категорию ASCII в VBA?

Это некоторые из символов, которые появляются в моей строке, которые необходимо удалить. Œ œ Š š Ÿ ƒ Есть еще много таких символов.

Это не относится к категории ASCII, как вы можете увидеть это http://www.ascii.cl/htmlcodes.htm

Я пытался что-то вроде этого

strName = Replace(strName, ChrW(376), " ") 

, но это не сработало.

Пожалуйста, помогите мне решить эту проблему.

Благодаря Jeevan

Answer 1

Будет ли RegEx решение будет представлять интерес для Вас?

На этом сайте представлено множество примеров для разных языков - вот C# 1: How can you strip non-ASCII characters from a string? (in C#).

Попробуйте для VBA:

Private Function GetStrippedText(txt As String) As String 
    Dim regEx As Object 

    Set regEx = CreateObject("vbscript.regexp") 
    regEx.Pattern = "[^\u0000-\u007F]" 
    GetStrippedText = regEx.Replace(txt, "") 

End Function 

Answer 2

попробовать application.clean()

будет удалить все непечатаемые символы

Answer 3

Что вы получаете, когда вы пишете следующее в ближайшем окне?

?Replace("ŸŸŸŸ", ChrW(376), "ale") 

я получаю: alealealeale

Answer 4

предположив, что вы есть:

Тогда следующий код получит String от A1 и пусть только через ANSI (код 0 до 255) в A2.

Sub test() 
Dim s1 As String, s2 As String, c As String, i As Long, iAsc As Integer 

s1 = Range("A1").Value 

s2 = "" 

For i = 1 To Len(s1) 
    c = Mid(s1, i, 1) 
    iAsc = AscW(c) 
    If iAsc <= 255 Then 
    s2 = s2 & c 
    End If 
Next 

Range("A2").Value = s2 

End Sub 

Answer 5

Попробовать ниже

Function ClearUnwantedString(fulltext As String) As String 
    Dim output As String 
    Dim character As String 
    For i = 1 To Len(fulltext) 
     character = Mid(fulltext, i, 1) 
     If (character >= "a" And character <= "z") Or (character >= "0" And character <= "9") Or (character >= "A" And character <= "Z") Then 
      output = output & character 
     End If 
    Next 
    ClearUnwantedString = output 
End Function 

Sub test() 
    a = ClearUnwantedString("dfjŒœŠdskl") 
End Sub