Perl: используя массив для создания хэш хэш структуры

Question

в цикле я извлечь

• Массив (его длина и данные могут меняться при каждой итерации)
• 1 Имя данных
• 1 Значение данных

И я хотел бы создать хэш хэш, имеющий в качестве структуры массив и установить в конце данные, полученные.

Exemple, если у меня есть:

@array = ('a','b','c'); 
$dataname = 'my data'; 
$datavalue = '123'; 

Я хотел бы иметь хэш, как показано ниже:

%hash = (
    a => { 
      b => { 
       c => { 
         'my data' => '123' 
         } 
       } 
      } 
     ); 

Но я не нашел где-нибудь, как это сделать.

Answer 1

вы можете сделать это таким образом, это не самый эффективный, но он работает

use Data::Dumper; 

my @array = ('a','b','c'); 
my $dataname = 'my data'; 
my $datavalue = '123'; 

my $hash = {$dataname => $datavalue}; 

foreach my $item (reverse @array){ 
    $hash = {$item =>$hash}; 
} 
my %hash =%$hash; 
print Dumper(\%hash); 

вы получите следующий результат:

$VAR1 = { 
      'a' => { 
        'b' => { 
          'c' => { 
            'my data' => '123' 
            } 
          } 
       } 
     }; 

Answer 2

use Data::Diver qw(DiveVal); 

DiveVal(\%hash, map \$_, @array, $dataname) = $datavalue; 

В качестве альтернативы,

sub DiveVal :lvalue { 
    my $p = \shift; 
    $p = \($$p->{$_}) for @_; 
    $$p 
} 

DiveVal(\%hash, @array, $dataname) = $datavalue;