Сознательное сообщение об ошибке для Clojure.Spec проверки в: pre

Question

Я использовал последние дни, чтобы копать глубже в clojure.spec в Clojure и ClojureScript.

До сих пор я нахожу его наиболее полезным, чтобы использовать спецификации в качестве охранников в :pre и :post в публичных функциях, которые полагаются на данные в определенном формате.

(defn person-name [person] 
    {:pre [(s/valid? ::person person)] 
    :post [(s/valid? string? %)]} 
    (str (::first-name person) " " (::last-name person))) 

Проблема с этим подходом в том, что я получаю java.lang.AssertionError: Assert failed: (s/valid? ::person person) без какой-либо информации о том, что именно не встретил спецификацию.

кто-нибудь идею , как получить лучшее сообщение об ошибке в :pre или :post охранников?

Я знаю о conform и explain*, но это не помогает в этих :pre или :post охранников.

Answer 1

Я думаю, что идея заключается в том, что вы используете spec/instrument для проверки ввода и вывода функций, а не условий предварительной и пост.

Есть хороший пример в нижней части этого сообщения в блоге: http://gigasquidsoftware.com/blog/2016/05/29/one-fish-spec-fish/. Краткое описание: вы можете определить спецификацию для функции, включая как входные, так и возвращаемые значения, используя ключи: args и: ret (таким образом, заменяя оба условия pre и post), с помощью spec/fdef, обработайте его, и вы получите результат, аналогичный использованию explain когда он не отвечает спецификации.

Minimal пример, полученный из этой ссылки:

(spec/fdef your-func 
    :args even? 
    :ret string?) 


(spec/instrument #'your-func) 

И это эквивалентно положить предпосылку, что функция имеет целочисленный аргумент и постусловие, что он возвращает строку. Кроме того, вы получаете гораздо более полезные ошибки, точно так же, как вы ищите.

Подробнее в официальном руководстве: https://clojure.org/guides/spec --- см. Под заголовком «Функции функции».

Answer 2

Не принимая во внимание, если вы должны использовать заранее и пост условия для проверки аргументов функции, существует способ печати несколько четких сообщений от до и после условий, окружив свой предикат с clojure.test/is, как это было предложено в ответ ниже:

How can I get Clojure :pre & :post to report their failing value?

Итак ваш код может выглядеть следующим образом:

(ns pre-post-messages.core 
    (:require [clojure.spec :as s] 
      [clojure.test :as t])) 

(defn person-name [person] 
    {:pre [(t/is (s/valid? ::person person))] 
    :post [(t/is (s/valid? string? %))]} 
    (str (::first-name person) " " (::last-name person))) 

(def try-1 
    {:first-name "Anna Vissi"}) 

(def try-2 
    {::first-name "Anna" 
    ::last-name "Vissi" 
    ::email "Anna@Vissi.com"}) 

(s/def ::person (s/keys :req [::first-name ::last-name ::email])) 

Оценка

pre-post-messages.core> (person-name try-2) 

будет производить

"Anna Vissi" 

и оценка

pre-post-messages.core> (person-name try-1) 

будет производить

Answer 3

В новых альф, есть теперь s/assert, которые могут быть использованы утверждать, что входной или возвращаемое значение соответствует спецификации. Если оно действительное, возвращается исходное значение. Если это неверно, с результатом объяснения возникает ошибка утверждения. Утверждения могут быть включены или выключены и могут быть необязательно исключены из скомпилированного кода целиком, чтобы иметь эффект 0 производства.

(s/def ::first-name string?) 
(s/def ::last-name string?) 
(s/def ::person (s/keys :req [::first-name ::last-name])) 
(defn person-name [person] 
    (s/assert ::person person) 
    (s/assert string? (str (::first-name person) " " (::last-name person)))) 

(s/check-asserts true) 

(person-name 10) 
=> CompilerException clojure.lang.ExceptionInfo: Spec assertion failed 
val: 10 fails predicate: map? 
:clojure.spec/failure :assertion-failed 
#:clojure.spec{:problems [{:path [], :pred map?, :val 10, :via [], :in []}], :failure :assertion-failed}