Распознавание лиц с opencv, open kinect и kinect v2 в обработке

Question

Я пытаюсь создать обнаружение лица с помощью библиотек opencv и openkinect. для ввода изображения я хочу использовать xbox kinect v2. Я основываю свой код на примере обнаружения лица в библиотеке opencv. Я работаю над Mac.

это мой код до сих пор:

import gab.opencv.*; 
import java.awt.Rectangle; 

/* KINECT */ 
import org.openkinect.freenect.*; 
import org.openkinect.freenect2.*; 
import org.openkinect.processing.*; 

OpenCV opencv; 
Kinect2 kinect2; 

Rectangle[] faces; 

void setup() { 
    opencv = new OpenCV(this, 640/2, 480/2); 
    size(640, 480); 
    // Kinectv2 
    kinect2 = new Kinect2(this); 
    kinect2.initVideo(); 
    kinect2.initDevice(); 

    opencv.loadCascade(OpenCV.CASCADE_FRONTALFACE); 
    faces = opencv.detect(); 
} 

void draw() { 
    opencv.loadImage(kinect2.getVideoImage()); 
    image(kinect2.getVideoImage(), 0, 0, 640, 480); 

    noFill(); 
    stroke(0, 255, 0); 
    strokeWeight(3); 
    for (int i = 0; i < faces.length; i++) { 
    rect(faces[i].x, faces[i].y, faces[i].width, faces[i].height); 
    } 
} 

проблема, как представляется, в строке "opencv.loadImage (kinect2.getVideoImage());" так как обнаружение не работает. при работе с камерой isight (с использованием встроенной функции «захват» и «видео» -add-on) вместо kinect все работает отлично.

Может ли кто-нибудь помочь?

Answer 1

В будущем, пожалуйста, постарайтесь предоставить MCVE. Это означает, что вы начинаете с чистого эскиза и добавляете достаточно кода, чтобы мы могли увидеть проблему. В вашем случае нам не нужно видеть какой-либо код kinect. Просто загрузите жестко кодированное изображение и передайте его в OpenCV.

Вот пример эскиза, который делает именно это. Я получил URL-адрес изображения от human Wikipedia page.

import gab.opencv.*; 
import java.awt.Rectangle; 

PImage image; 
OpenCV opencv; 

void setup() { 
    size(500, 500); 
    image = loadImage("https://upload.wikimedia.org/wikipedia/commons/thumb/2/27/A_young_Man_and_Lady.png/800px-A_young_Man_and_Lady.png"); 
    image.resize(width, height); 

    opencv = new OpenCV(this, width, height); 
    opencv.loadCascade(OpenCV.CASCADE_FRONTALFACE); 
} 

void draw() { 

    image(image, 0, 0); 

    opencv.loadImage(image); 
    Rectangle[] faces = opencv.detect(); 

    noFill(); 
    stroke(255, 0, 0); 
    strokeWeight(3); 
    for (Rectangle face : faces) { 
    rect(face.x, face.y, face.width, face.height); 
    } 
} 

Обратите внимание, что я звоню opencv.detect() функцию каждый кадр. Вы звоните только от setup(), что означает, что вы только обнаруживаете лица в самом первом кадре.

Если вы все еще не можете заставить его работать, вам придется выполнить некоторую отладку. Постарайтесь изолировать свою проблему как можно больше. Избавьтесь от кода kinect и просто используйте жестко кодированное изображение. Возьмите захват экрана изображения, полученного через ваш kinect, и используйте это вместо прямого потока. Работайте на более мелких шагах, таким образом, вы можете опубликовать более конкретный вопрос, когда вы застряли (трудно помочь с общим вопросом «это не работает» - гораздо проще помочь с конкретным «Я попробовал X, ожидаемый Y», но Z вместо этого задавали вопросы типа. Удачи.