Замена домена в JENA Triplestore

Question

Я хочу заменить сервер всех моих предметов, хранящихся в моем трехэтажном магазине в Йене.

Я пробовал этот способ, но сервер не будет заменен ...

DELETE { ?s ?p ?o } 
INSERT { ?s1 ?p ?o } 
WHERE { 
    { SELECT (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) 
     { 
      ?s ?p ?o . 
      FILTER regex(str(?s), '^https://somedomain.org/') 
     } 
    } 
} 

Когда я только выполнить следующий запрос

SELECT (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) ?s 
{ 
    ?s ?p ?o . 
    FILTER regex(str(?s), '^https://somedomain.org/') 
} 

'? S' и '? S1' делать имеют правильные значения.

Похоже, что в блоке DELETE/INSERT доступно значение '? S' и '? S1'. Что случилось с моим запросом обновления?

Answer 1

Ваша проблема заключается в том, что вы используете подзапрос в своем обновлении, и вы создаете только проект ?s1 из вашего подзапроса.

Это означает, что вне подзапроса не видны ?s, ?p и ?o. Поэтому, когда шаблоны и INSERT пытаются создать троек для удаления и вставить все троек, которые они строят, являются недействительными (потому что не все переменные видны), и поэтому ничего не меняется.

Чтобы исправить это, вы должны либо проецировать все соответствующие переменные:

DELETE { ?s ?p ?o } 
INSERT { ?s1 ?p ?o } 
WHERE 
{ 
    { 
    SELECT ?s ?p ?o (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) 
    { 
     ?s ?p ?o . 
     FILTER regex(str(?s), '^https://somedomain.org/') 
    } 
    } 
} 

Или следовать Joshua Taylor's предложение от комментариев. Это на самом деле лучше, так как упрощает общий запрос:

DELETE { ?s ?p ?o } 
INSERT { ?s1 ?p ?o } 
WHERE 
{ 
    ?s ?p ?o . 
    FILTER regex(str(?s), '^https://somedomain.org/') 
    BIND(uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) 
}