Скопируйте узел и добавьте значение в атрибут с Xslt

Question

У меня проблема с xml и xslt, о которой я не знаю, как решить, и был бы признателен за любую помощь в этом вопросе, с чего начать. У меня есть XML:

<root> 
<test value="1" setting="3"> 
    <tag1>data....</tag1> 
    <tag2>data....</tag2> 
    <tag n+1>data....</tag n+1> 
</test> 
<test value ... 
. 
. 
. 
</test> 
</root> 

Теперь я бы сейчас нужно скопировать, все узлы в узле «тест» таким образом и добавить всегда значение 3 настройки (значение параметров меняется в тестовом узле) в 4-х новых узлов как показано ниже, так что я хотел бы получить:

<root> 
<test value="2" setting="6"> 
    <ni1 name="1" setting1="6">data....</ni1> 
    <ni2 name="1" setting1="6">data....</ni2> 
    <ni3 name="1" setting1="6">data....</ni3> 
    <ni4 name="1" setting1="6">data....</ni4> 
    <tag1>data....</tag1> 
    <tag2>data....</tag2> 
    <tag n+1>data....</tag n+1> 
</test> 
<test value ... 
. 
. 
. 
</test> 
</root> 

Спасибо большое за любую помощь по этому вопросу, eoglasi

Answer 1

Как уже упоминалось в комментариях identity transform является то, что вам нужно, когда вы преобразования XML и только хотите внести изменения в определенные части из XML

<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

Вы говорите, что вы хотите «добавить всегда значение 3 настройки», так что вы бы иметь шаблон, соответствующий настройки атрибута.

<xsl:template match="test/@setting"> 

(В данном случае, это будет соответствовать только настройки атрибут, который принадлежит к тест элемента.)

И тогда в этом шаблоне вы затем использовать XSL: атрибут для вывода новый атрибут, а не с тем же именем, но с измененным значением

<xsl:attribute name="setting"> 
    <xsl:value-of select="number(.) + 3" /> 
</xsl:attribute> 

вы говорите, что вы хотите скопировать 4 узла под тест узел. Это означает, что вам нужен шаблон, чтобы соответствовать тест узел, как это то, что вам нужно преобразовать, чтобы добавить детей

<xsl:template match="test"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*" /> 
    <!-- Add new nodes here --> 
    <xsl:apply-templates select="node()"/> 
    </xsl:copy> 
</xsl:template> 

Не ясно, где данные для ваших новых узлов приходит, так что вы будете иметь сделать это самостоятельно, но это похоже на то, что атрибут атрибут исходит из атрибута на тестовом элементе. Таким образом, ваш код может быть таким:

<ni1 name="1" setting1="{number(@setting) + 3}">data....</ni1> 

Обратите внимание на использование шаблонов значений атрибутов здесь. Фигурные фигурные скобки { } указывают выражение, которое должно оцениваться, а не выводиться буквально.

Попробуйте этот XSLT в качестве образца.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="test/@setting"> 
    <xsl:attribute name="setting"> 
     <xsl:value-of select="number(.) + 3" /> 
    </xsl:attribute> 
    </xsl:template> 

    <xsl:template match="test"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*" /> 
     <ni1 name="1" setting1="{number(@setting) + 3}">data....</ni1> 
     <xsl:apply-templates select="node()"/> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet>