Битовые операции - проверка и удаление

Question

Примечание простой пример ниже:

Module Module1 
    <Flags> 
    Public Enum Names 
     None = 0 
     Test = 1 
     Test2 = 2 
     Test3 = 4 
     Test4 = 8 
    End Enum 

    Sub Main() 
     Dim test As Names = Names.Test Or Names.Test3 
     If (test And Names.Test3) = Names.Test3 
      Console.WriteLine("TRUE") 
     Else 
      Console.WriteLine("FALSE") 
     End If 
    End Sub 
End Module 

Первая часть моего вопроса относится к линии If (test And Names.Test3) = Names.Test3.

Не было бы лучше просто проверить If test And Names.Test3, как если бы флаг существовал? Если он оценивает ненулевое значение (то есть флаг существует), то результатом этого условия будет True в любом случае.

Есть ли веская причина использовать первый способ проверки второго? (Хотя мой ответ для VB.NET, мне также было бы интересно узнать, является ли это потенциальной ловушкой в ​​другом месте, то есть C#, C++ и т. Д.).

Кроме того, в отношении удаления флага, кажется, есть два способа сделать это:

test = test Xor Names.Test3 и test = test And Not Names.Test3

Тем не менее, первый добавит флаг, если он отсутствует, и удалить его, если он там, тогда как второй удалит его только. Разве это единственная разница? Или есть еще одна причина, почему я должен предпочесть один метод другому?

Answer 1

Вы правы в том, что вы можете эффективно заменить это:

If (test And Names.Test3) = Names.Test3 Then

с этим

If (test And Names.Test3) Then

Но, второй пример не будет компилировать с Option Strict On, как вы правильно получить ошибку:

Option Strict On disallows implicit conversions from 'Names' to 'Boolean' поэтому, чтобы получить это, вам нужно обернуть вокруг него CBool.

Итак, в заключение я бы сказал, что лучше использовать первый пример, поскольку цель очень ясна: - вы проверяете, установлен ли бит.

С точки зрения удаления флага т.е. незаходимого бит следует использовать:

test = test And Not Names.Test3

Использование Xor имеет эффект переключая значения.

Следующая может помочь (особенно, если вы сделаете их методы расширения):

Public Function SetBit(ByVal aValue As Names, ByVal aBit As Names) As Names 
    Return (aValue Or aBit) 
End Function 

Public Function ClearBit(ByVal aValue As Names, ByVal aBit As Names) As Names 
    Return (aValue And Not aBit) 
End Function 

Public Function IsBitSet(ByVal aValue As Names, ByVal aBit As Names) As Boolean 
    Return ((aValue And aBit) = aBit) 
End Function 

Public Function ToggleBit(ByVal aValue As Names, ByVal aBit As Names) As Names 
    Return (aValue Xor aBit) 
End Function 

Answer 2

Помните, что Flags перечислений не должны все быть чисто едиными битовыми значениями. Например. представьте (с лучшими именами), что ваше перечисление было:

<Flags> 
Public Enum Names 
    None = 0 
    Test = 1 
    Test2 = 2 
    Test3 = 4 
    Test4 = 8 
    Test2AndTest4 = 10 
End Enum 

Теперь, вы не хотели бы, чтобы просто проверить, что test And Names.Test2AndTest4 отличен от нуля, так что не дает ответа на вопрос, правильный. Так что лучше привыкнуть, в общем, к And вашей маске, чтобы проверить, а затем сравнить с значением маски, чтобы гарантировать, что все бит маски установлен.