Как получить путь к текущему выбранному файлу

Question

Имеет ли VBScript функцию для получения пути к текущему выбранному файлу в Проводнике? Если да, то какова функция? Я ищу что-то вроде

Set fileObj = CreateObject("Scripting.FileSystemObject") 
dim filepath 
filepath = fileObj.GetCurrentSelection() 'doesn´t exist 
dim result 
result = filepath 'communicate with LiveCode 

Answer 1

Я написал простой пример.
Имейте в виду, что может быть более одного открытого окна проводника Windows, и это отобразит их все.

Function GetSelectedFiles() 'Returns paths as array of strings 
    Dim FileList, Window, SelectedItem 
    'avoid duplicates by storing paths in dictionary keys 
    Set FileList = CreateObject("Scripting.Dictionary") 

    With CreateObject("Shell.Application") 
     For Each Window In .Windows 
      'skip IE Windows 
      If InStr(1, Window.FullName, "iexplore.exe", vbTextCompare) = 0 Then 
       For Each SelectedItem In Window.Document.SelectedItems 
        FileList(SelectedItem.Path) = Null 
       Next 
      End If 
     Next 
    End With 

    GetSelectedFiles = FileList.Keys 'array of paths 
End Function 

MsgBox "Click OK after selecting the items", _ 
     vbOKOnly Or vbInformation, "Select a few items" 

Dim SelectedFiles 
    SelectedFiles = GetSelectedFiles 

MsgBox "You selected: " & vbNewLine & vbNewLine & _ 
     Join(SelectedFiles, vbNewLine), vbOKOnly Or vbInformation, "Selected Items" 

'loop through array 
'Dim FileItem 
'For Each FileItem In SelectedFiles 
' WScript.Echo FileItem 
'Next 

Answer 2

попробовать это с помощью этого вы можете получить путь к выбранной в данный момент file.you также необходимо

Set objFS=CreateObject("Scripting.FileSystemObject") 
    Set objArgs = WScript.Arguments 
    strFile= objArgs(0) 
    Set objFile = objFS.OpenTextFile(strFile) 
    Set objFile = objFS.GetFile(strFile) 
    WScript.Echo objFile.Path