Prolog - Как ограничить длину списка переменных

Question

У меня возникли проблемы с созданием всех списков, соответствующих определенным критериям.

city(new_york, 47). 
city(chicago, 100). 

all_unique([]). 
all_unique([H|T]) :- H = [] ; (not(member(H, T)), all_unique(T)). 

cities([Head|Tail]) :- 
    length(Tail, L), 
    L < 2, 
    city(Head, _A), 
    (Tail = [] ; cities(Tail)). 

Когда я выполняю запрос cities(L), я хочу, чтобы создать все списки городов с максимальной длиной 2 и без повторения. Теперь он возвращает все возможные списки, а затем сохраняет списки попыток, которые явно не соответствуют критериям.

?- cities(L). 
L = [new_york] ; 
L = [chicago] ; 
L = [new_york, new_york] ; 
L = [new_york, chicago] ; 
L = [chicago, new_york] ; 
L = [chicago, chicago] ; 
ERROR: Out of global stack 
?- 

Как сообщить Прологу, чтобы он не пробовал слишком длинные списки или повторял элементы?

Answer 1

Ваше определение all_unique/1 лучше основано на prolog-dif:

all_unique([]). 
all_unique([E|Es]) :- 
    maplist(dif(E), Es), 
    all_unique(Es). 

основе meta-predicatemaplist/2 вы можете определить cities/1 так:

city_(new_york, 47). 
city_(chicago, 100). 

city(C) :- 
    city_(C, _). 

cities(List) :- 
    length(Ref, 2), 
    append(List, _, Ref), 
    all_unique(List), 
    maplist(city, List). 

Пример запроса:

?- cities(Xs). 
Xs = [] ; 
Xs = [new_york] ; 
Xs = [chicago] ; 
Xs = [new_york, chicago] ; 
Xs = [chicago, new_york] ; 
false.         % terminates universally