список всех стран в двух списках со списком в форме в vb.net

Question

Imports System.Collections.Generic 
Imports System.Globalization 
Public Sub ListCountries(SourceCombo As System.Windows.Forms.ComboBox) 
     ' Iterate the Framework Cultures... 
     For Each ci As CultureInfo In CultureInfo.GetCultures(CultureTypes.AllCultures) 
      Dim ri As RegionInfo 
      Try 
       ri = New RegionInfo(ci.Name) 
      Catch 
       'If a RegionInfo object could not be created don't use the CultureInfo for the country list. 
       Continue For 
      End Try 
      ' Create new country dictionary entry. 
      Dim newKeyValuePair As New KeyValuePair(Of String, String)(ri.EnglishName, ri.ThreeLetterISORegionName) 
      ' If the country is not already in the countryList add it... 
      If Not countryList.ContainsKey(ri.EnglishName) Then 
       countryList.Add(newKeyValuePair.Key, newKeyValuePair.Value) 
       SourceCombo.Items.Add(ri.EnglishName) 
      End If 
     Next 
     SourceCombo.Sorted = True 

    End Sub 

Я добавил три комбинированные коробки в форму и трижды вызывал вышеупомянутую функцию для каждого поля со списком в событии загрузки формы. как: listcountries (ComboBox1) listcountries (ComboBox2) listcountries (ComboBox3)

но первый выпадающий только перечисляет все страны, а две другие являются пустыми. пожалуйста, помогите мне, как это решить.

им с помощью vb.net 12 Конечных & окна 7

спасибо

Answer 1

Почему бы не вернуть список объектов страны и привязать к каждому выпадающему списку с использованием источника данных?

Также элементы добавляются в comboxbox, если в списке стран нет, поэтому необходимо удалить список стран. Он должен быть comboxbox.Items.Contains()

Answer 2

Словарь CountryList является глобальным для вашего класса и инициализируется где-то перед вызовом этого метода. Таким образом, первый вызов находит словарь пустым и добавляет информацию как к словарю, так и к комбо, но второй вызов (и третий) находит словарь уже заполненным и, таким образом, не добавляет ничего ко второму (и третьему) комбо

Без воссоздании словарь каждый раз, когда вы вызываете этот метод, вы могли бы написать

Dim countryList as SortedDictionary(Of string, String) 

Public Sub ListCountries(SourceCombo As System.Windows.Forms.ComboBox) 
    If countryList Is Nothing Then 
     countryList = BuildCountryList() 
    End If 
    SourceCombo.DisplayMember = "Key" 
    SourceCombo.ValueMember = "Value" 
    SourceCombo.DataSource = New BindingSource(countryList, Nothing) 
    ' No need to sort anything   
End Sub 

Public Function BuildCountryList() As SortedDictionary(Of String, String) 
    Dim temp = New SortedDictionary(Of String, String) 
    For Each ci As CultureInfo In CultureInfo.GetCultures(CultureTypes.AllCultures) 
     Dim ri As RegionInfo 
     Try 
      ri = New RegionInfo(ci.Name) 
     Catch 
      'If a RegionInfo object could not be created don't use the CultureInfo for the country list. 
      Continue For 
     End Try 
     ' If the country is not already in the countryList add it... 
     If Not temp.ContainsKey(ri.EnglishName) Then 
      temp.Add(ri.EnglishName, ri.ThreeLetterISORegionName) 
     End If 
    Next 
    Return temp 
End Function