Сопоставьте слова, представленные в строке. Если слова повторяются в предложении, они дают сообщение «Матч», иначе выдается сообщение «Нет совпадения»

Question

Я являюсь tyring, чтобы сделать программу, которая принимает предложение как входную информацию, а затем разбивает на нее разные слова. Теперь он сравнивает слова, и если слово повторяется, то дает сообщение, иначе оно не дает совпадения. Но при выполнении этого не отображается MsgBox.

Это сценарий, который я написал:

Dim sent 
Dim i 
Dim j 
Dim k 
sent = "Its a good day but every day is a good day" 
words = Array(Split(sent)) 
For i = LBound(words) To UBound(words)-1 
    For j = LBound(words)+1 To UBound(words) 
    k = StrComp(words(i), words(j)) 
    If k=0 Then 
     MsgBox ("Match") 
    Else 
     MsgBox ("No Match") 
    End If 
    Next 
Next 

Answer 1

Цикл For никогда не будет работать, потому что UBound(words) вернется 0.

Это происходит потому, что функция Split() возвращает Array поэтому нет никакой необходимости в дополнительной Array() вызова, который заканчивает тем, что дает вам один элемент массива, содержащий другой массив.

Решение изменить

words = Array(Split(sent)) 

в

words = Split(sent) 

Это будет исправить вашу исходную задачу, но есть и другие проблемы, связанные с кодом вам нужно будет обратиться, прежде чем он работает правильно.

Answer 2

Инструмент VBScript для классификации/подсчета токенов типов/распознавания является Dictionary.

Демо:

Option Explicit 

Dim a : a = Split("Its a good day but every day is a good day") 
Dim d : Set d = CreateObject("Scripting.Dictionary") 
Dim w 
For Each w In a 
    d(w) = d(w) + 1 
    If 1 < d(w) Then 
     WScript.Echo "more than one " & w & " - could 'Exit For'" 
    End If 
Next 
For Each w In d.Keys() 
    WScript.Echo w, d(w) 
Next 

(! Внешний вид ма, без вложенных циклов)

выход:

cscript 42004404.vbs 
more than one day - could 'Exit For' 
more than one a - could 'Exit For' 
more than one good - could 'Exit For' 
more than one day - could 'Exit For' 
Its 1 
a 2 
good 2 
day 3 
but 1 
every 1 
is 1