cons :: оператор для последовательностей в F #?

Question

Есть ли лучший код, который не нуждается в преобразовании последовательности в список?

let rec addentry map keys = 
    match keys with 
    | ((i,j) :: tail) -> Map.add (i,j) ((inputd.[i]).[j]) (addentry map tail) 
    | ([]) -> map 

addentry Map.empty (Cartesian keys1 keys2 |> Seq.toList) 

Answer 1

Это прекрасное место для использования Seq.fold. Он сворачивает коллекцию в одно значение.

Cartesian keys1 keys2 
|> Seq.fold (fun map (i, j) -> 
    let value = (inputd.[i]).[j] 
    Map.add (i, j) value map) Map.empty 

Answer 2

Cartesian keys1 keys2 
|> Seq.map (fun (i, j) -> ((i, j), (inputd.[i]).[j])) 
|> Map.ofSeq 

Answer 3

В дополнение к предыдущим ответам, если вы хотите, чтобы иметь возможность сопоставления с образцом последовательности, можно определить активный шаблон:

let (|Cons|Nil|) s = 
    if Seq.isEmpty s then 
     Nil 
    else 
     Cons(Seq.head s, Seq.skip 1 s) 

let rec addentry map keys = 
    match keys with 
    | Cons((i,j), tail) -> Map.add (i,j) ((inputd.[i]).[j]) (addentry map tail) 
    | Nil -> map