Я хотел бы написать генератор лексера, чтобы преобразовать базовое подмножество языка Matlab в C#, C++ и т. Д. Чтобы помочь мне это сделать, я хотел бы найти документ, содержащий формальную грамматику для matlab. Проведя немного времени, исследуя это, кажется, что mathworks не обеспечивают его. Кто-нибудь знает, где я могу найти такой документ?Где я могу найти формальную грамматику для Matlab?
Отличной возможность написать свою собственную формальную грамматику :)
Если вы должны выбрать, чтобы писать тот GRAMMER вашей собственную личность, я могу рекомендовать BNFC, которые могут принимать формальную грамматику BNF и построение структур данных и лексические/парсеров для пара целевых языков (C/C++, C#, Java, Haskell и т. д.). Это сэкономит вам много времени и позволит сосредоточиться на формулировании грамматики, а затем получить право на внедрение конвертера на вашем предпочтительном языке.
Если ничего другого, ссылка на BNFC содержит некоторую помощь и указатели на то, как сформулировать грамматику BNF. Удачи!
Спасибо за совет, я посмотрю. Я думал об использовании fslex и fsyacc. –
Это не полная грамматика, но yacc-keable for matlab предоставляется для компилятора в 2000 году. С этого момента вы можете легко создавать BNF и EBNF.
primary_expression
: IDENTIFIER
| CONSTANT
| STRING_LITERAL
| '(' expression ')'
| '[' ']'
| '[' array_list ']'
;
postfix_expression
: primary_expression
| array_expression
| postfix_expression TRANSPOSE
| postfix_expression NCTRANSPOSE
;
index_expression
: ':'
| expression
;
index_expression_list
: index_expression
| index_expression_list ',' index_expression
;
array_expression
: IDENTIFIER '(' index_expression_list ')'
;
unary_expression
: postfix_expression
| unary_operator postfix_expression
;
unary_operator
: '+'
| '-'
| '~'
;
multiplicative_expression
: unary_expression
| multiplicative_expression '*' unary_expression
| multiplicative_expression '/' unary_expression
| multiplicative_expression '\\' unary_expression
| multiplicative_expression '^' unary_expression
| multiplicative_expression ARRAYMUL unary_expression
| multiplicative_expression ARRAYDIV unary_expression
| multiplicative_expression ARRAYRDIV unary_expression
| multiplicative_expression ARRAYPOW unary_expression
;
additive_expression
: multiplicative_expression
| additive_expression '+' multiplicative_expression
| additive_expression '-' multiplicative_expression
;
relational_expression
: additive_expression
| relational_expression '<' additive_expression
| relational_expression '>' additive_expression
| relational_expression LE_OP additive_expression
| relational_expression GE_OP additive_expression
;
equality_expression
: relational_expression
| equality_expression EQ_OP relational_expression
| equality_expression NE_OP relational_expression
;
and_expression
: equality_expression
| and_expression '&' equality_expression
;
or_expression
: and_expression
| or_expression '|' and_expression
;
expression
: or_expression
| expression ':' or_expression
;
assignment_expression
: postfix_expression '=' expression
eostmt
: ','
| ';'
| CR
;
statement
: global_statement
| clear_statement
| assignment_statement
| expression_statement
| selection_statement
| iteration_statement
| jump_statement
;
statement_list
: statement
| statement_list statement
;
identifier_list
: IDENTIFIER
| identifier_list IDENTIFIER
;
global_statement
: GLOBAL identifier_list eostmt
;
clear_statement
: CLEAR identifier_list eostmt
;
expression_statement
: eostmt
| expression eostmt
;
assignment_statement
: assignment_expression eostmt
;
array_element
: expression
| expression_statement
;
array_list
: array_element
| array_list array_element
;
selection_statement
: IF expression statement_list END eostmt
| IF expression statement_list ELSE statement_list END eostmt
| IF expression statement_list elseif_clause END eostmt
| IF expression statement_list elseif_clause
ELSE statement_list END eostmt
;
elseif_clause
: ELSEIF expression statement_list
| elseif_clause ELSEIF expression statement_list
;
iteration_statement
: WHILE expression statement_list END eostmt
| FOR IDENTIFIER '=' expression statement_list END eostmt
| FOR '(' IDENTIFIER '=' expression ')' statement_list END eostmt
;
jump_statement
: BREAK eostmt
| RETURN eostmt
;
translation_unit
: statement_list
| FUNCTION function_declare eostmt statement_list
;
func_ident_list
: IDENTIFIER
| func_ident_list ',' IDENTIFIER
;
func_return_list
: IDENTIFIER
| '[' func_ident_list ']'
;
function_declare_lhs
: IDENTIFIER
| IDENTIFIER '(' ')'
| IDENTIFIER '(' func_ident_list ')'
;
function_declare
: function_declare_lhs
| func_return_list '=' function_declare_lhs
;
Dave Wingate предоставляет некоторые ресурсы Antler, которые выглядят как отличное место для начала. Как отмечено в его файле README, он не включает оператор транспонирования и несколько других сложных анализов. См mparser ссылки здесь:
http://web.mit.edu/~wingated/www/resources.html
Некоторые из сложных битых более ранних версий Matlab (1999), также описаны в документе группы из Северо-Западного. Он включает в себя описания, подобные EBNF. Он также описывает некоторые неприятные фрагменты в некоторых сносках.
http://www.ece.northwestern.edu/cpdc/pjoisha/MAGICA/CPDC-TR-9909-017.pdf
Я собрал несколько других менее соответствующих источников, но редактор бот StackOverflow говорит мне не хватает точки репутации размещать более двух ссылок.
Вы можете начать с адаптации преобразователя MATLAB -> Python smop, который сам написан на Python. Он использует PLY (Python lex - yacc). Файлы, которые, скорее всего, вас интересуют, начинаются с lexer.py и parse.py.
См. Также this answer для перечня преобразователей с MATLAB на Python.
Я сильно подозреваю, что Mathworks не определяет формальную грамматику для Matlab. Я буду следить за ответами на этот вопрос. –
Октава анализирует грамматику Матлаба. Возможно, стоит проверить, что они уже сделали. –
Файл [lex file] (http://hg.savannah.gnu.org/hgweb/octave/file/c1f9b54350f9/src/lex.ll) в источнике Octave полезен. Я также нашел [antl parser] (http://www.antlr.org/pipermail/antlr-interest/2011-September/042551.html), который преобразует matlab в C и Java. –