не удалось создать ошибку и перенаправить ее в файл в perl

Question

Я пытаюсь перенаправить STDOUT и STDERR в какой-то файл. В какой-то степени я добился успеха. Но я не могу понять одну вещь в приведенном ниже коде.

#!/usr/bin/perl 
open (STDOUT,">/var/tmp/outfile") or die "problem : $!"; 
open (STDERR,">>/var/tmp/outfile") or die "problem : $!"; 
print "$_\n" foreach (1..10); 
sdsdf; # buggy line inserted wantedly 

я вставил последнюю строку в предположении, что Perl будет разлетом ошибки и будет перенаправлен в файл, но его не происходит. Моя программа не распространяется на любую ошибку на экране или в outfile. Пожалуйста, помогите мне понять это поведение.

Answer 1

Без use strict;,

sdsdf; 

такая же, как

"sdsdf"; 

Это одна из причин, почему вы всегда хотите использовать use strict; use warnings;. Начнем с добавления этого.

---

Таким образом, вы хотите регистрировать весь вывод, включая ошибки времени компиляции, в файл. Ну, это не произойдет, перенаправив STDERR после того, как ваш код был скомпилирован. Лучший способ сделать это - вне вашей программы.

script.pl >/var/tmp/outfile 2>&1 

, но это может быть сделано из вашей программы.

#!/usr/bin/perl 
use strict; 
use warnings; 

BEGIN { 
    open(STDOUT, '>', '/var/tmp/outfile') 
     or die("Can't redirect STDOUT: $!\n"); 
    open(STDERR, '>&', \*STDOUT) 
     or die("Can't redirect STDERR: $!\n"); 
} 

print "$_\n" foreach (1..10); 
sdsdf; # Syntax error 

Answer 2

sdsdf не генерирует никаких ошибок (если вы use strict, тогда вы увидите некоторые ошибки времени компиляции), поэтому вы не видите никаких сообщений. Попробуйте следующее:

use warnings; 
use strict; 
open (STDOUT,">outfile1") or die "problem : $!"; 
open STDERR, ">&STDOUT"; 
print "$_\n" foreach (1..10); 
die("aaaa"); # buggy line inserted wantedly 

Также в вашем коде вы дважды открываете один и тот же файл, это может вызвать некоторые проблемы. В приведенном выше случае мы сначала перенаправляем stdout в файл, а затем перенаправляем stderr на stdout.