Пролог ограничение

Question

У меня есть 3 Ограничения для списка:

1. списка Ins 1..9
2. all_different (список)

3. списков в списке -> я получаю некоторые списки из списка , каждый список из списка должен выполнять ограничение без разрыва. например:

   List1 = [1,3,2,4];
   List2 = [3,2,1];
   List3 = [5,7,6]
   НЕПРАВИЛЬНО: песни4 = [1,4,3]
   

1 Вопрос: У вас есть идея, чтобы установить ограничение 3? Я бы сортировал списки и проверял: Element1 = Element2 + 1?

В конце концов я хочу использовать маркировку ([далее], список)

2 Вопрос: Я получаю решение с маркировкой, если я установить contraint 3, как моя идея?

Answer 1

Я думаю, что это по линии того, что вы ищете ...

:- use_module(library(clpfd)). 

foo(L) :- 
    Len in 1..9, % lists of length 1 through 9 
    length(L, Len), 
    L ins 1..9, 
    label(L), 
    msort(L, LS), 
    series(LS). 

series([_]). 
series([X,Y|T]) :- Y #= X + 1, series([Y|T]). 

Поскольку вы уже сдерживая список к определенному поведению серии, с указанием all_different было бы излишним.

Другой подход может быть:

foo(L) :- 
    [Fst,Lst] ins 1..9, 
    Fst #=< Lst, 
    Len #= Lst - Fst + 1, 
    length(L, Len), 
    label([Fst,Lst]), 
    L ins Fst..Lst, 
    all_different(L), 
    label(L). 

Эти предикаты генерировать все возможные списки, отвечающие критериям, и должны добиться успеха, если и только если данный список соответствует критериям.

Answer 2

Это может быть и то, что вы ищете. Без сортировки, просто использование maximum и minimum:

:- use_module(library(clpfd)). 

listl(LSize, List) :- 
    length(List, LSize), 
    domain(List, 1, 9), 

    maximum(MaxL, List), 
    minimum(MinL, List), 

    all_different(List), 
    LSize #= MaxL - MinL + 1, 

    labeling([], List). 

С небольшой тест:

| ?- listl(4, L). 
L = [1,2,3,4] ? ; 
L = [1,2,4,3] ? ; 
L = [1,3,2,4] ? ; 
L = [1,3,4,2] ? 
yes 
| ?- 

Отказ от ответственности: Вопрос трудно было понять.