MIPS - адрес выборки не выровнен по границе слова

Question

Я довольно новичок в программировании и программировании сборки в целом, и я стараюсь учиться. У меня возникли проблемы с хранением входных данных для переменных, можете ли вы мне помочь?

Проблема возникает, когда я загружаю адреса n1 и n2 или что-то в этом роде. Я попытался найти похожие проблемы и не могу их хорошо перевести. Если кто-то имеет какие-либо онлайн-ссылки для обучения, то это было бы весьма признательно.

Вот мой код:

.data 
prompt_n1: .asciiz "Enter first integer n1: " 
prompt_n2: .asciiz "Enter second integer n2: " 

debug_print: .asciiz "Your numbers are: " 

n1: .word 0 
n2: .word 0 

.text 

main: 
#Prompt the user for n1. 
li $v0, 4 
la $a0, prompt_n1 
syscall 

#Store console: n1 
li $v0, 5 
syscall 

#Attempts to load value of v0 into n1 - Problem Here 
la $t0, n1 
lw $t1, 0($v0) 
sw $t0, 0($t1) 

#Prompt the user for n2. 
li $v0, 4 
la $a0, prompt_n2 
syscall 

#Store console: n2 
li $v0, 5 
syscall 

#Attempts to load value of v0 into n1 - Problem Here 
la $t0, n2 
lw $t4, 0($v0) 
sw $t0, 0($t4) 

j print_statement 

print_statement: 
li $v0, 4 
la $a0, debug_print 
syscall 

li $v0, 1 
lw $a0, n1 
syscall 

li $v0, 1 
lw $a0, n2 
syscall 

Спасибо за ваше время и помощь.

Answer 1

Несколько проблем ...

После выполнения syscall 5, чтобы получить значение пользователя, то в $v0. Вы пытались передать это $t1 с помощью инструкции lw. Но вы использовали $v0 в качестве базового адреса lw. Если введенное значение пользователь был не кратно четырем, то это вызовет исключение выравнивания [как вы получили]

Что ты хотел move [зарегистрироваться для регистрации] и не нагрузки из памяти. Но, на самом деле, вам действительно не нужно было это делать.

Скорее просто разместите $v0 в n1, на который указывает $t0. Итак, ваш sw также неверен.

Кроме того, из-за n1 и n2были не первые пункты после .data директив, они могли не быть выровнены по границе в четыре байта, так как они должны использовать lw/sw на них. Итак, вам нужна директива .align.

Эти вопросы были повторены для ввода n2.

И после печати не было ничего, что могло бы остановить программу, поэтому она продолжала бы работать, пытаясь получить и выполнить инструкции с независимо от того, были ли в этой памяти случайные значения. Программе требуется syscall для правильного завершения выполнения, когда это будет сделано.

Я аннотированный код, показывающий до и после того, как, с исправлением ошибок [Pardon пожалуйста безвозмездная ыборкой стиля]:

.data 
prompt_n1: .asciiz  "Enter first integer n1: " 
prompt_n2: .asciiz  "Enter second integer n2: " 

debug_print: .asciiz "Your numbers are: " 
space:   .asciiz " " 

# NOTE/BUG: because of the variable length byte arrays above (i.e. the .asciiz 
# directives), these may not be aligned to a four byte boundary. there are two 
# solutions: 
# (1) place n1 and n2 immediately after the .data directive 
# (2) add a .align directive [as below] 
      .align  4 
n1:   .word  0 
n2:   .word  0 

    .text 

main: 
    # Prompt the user for n1. 
    li  $v0,4 
    la  $a0,prompt_n1 
    syscall 

    # Store console: n1 
    li  $v0,5 
    syscall 

    # Attempts to load value of v0 into n1 - Problem Here 
    la  $t0,n1 

    # NOTE/BUG: this is incorrect for several reasons: 
    # (1) $v0 has a value input by the user -- it could be 0, 1, etc. 
    # (2) these are not valid data addresses 
    # (3) if the user enters a value that is _not_ a multiple of four, it 
    #  generates an alignment exception 
    # (4) this instruction is just not needed and is just wrong 
    ###lw  $t1,0($v0) 

    # NOTE/BUG: $t1 has _not_ been set -- this should use the [correctly] set 
    # register $t0 [which has the address of n1] and should store the value 
    # read from the user 
    ###sw  $t0,0($t1) 
    sw  $v0,0($t0) 

    # Prompt the user for n2. 
    li  $v0,4 
    la  $a0,prompt_n2 
    syscall 

    # Store console: n2 
    li  $v0,5 
    syscall 

    # Attempts to load value of v0 into n1 - Problem Here 
    # NOTE/BUG: the lw is commented out for the same reason as above and has 
    # a similar mistake as above 
    la  $t0,n2 
    ###lw  $t4,0($v0) 
    ###sw  $t0,0($t4) 
    sw  $v0,0($t0) 

    j  print_statement 

print_statement: 
    li  $v0,4 
    la  $a0,debug_print 
    syscall 

    li  $v0,1 
    lw  $a0,n1 
    syscall 

    # NOTE/BUG: added this to separate the numbers 
    li  $v0,4 
    la  $a0,space 
    syscall 

    li  $v0,1 
    lw  $a0,n2 
    syscall 

    # NOTE/BUG: there was no more code here so it just "falls off the end of 
    # the world" -- we need to terminate program execution correctly with the 
    # exit syscall 
    li  $v0,10 
    syscall 

---

Некоторых ресурсами:

http://www.mrc.uidaho.edu/mrc/people/jff/digital/MIPSir.html

http://courses.missouristate.edu/kenvollmar/mars/help/syscallhelp.html

http://logos.cs.uic.edu/366/notes/mips%20quick%20tutorial.htm

http://chortle.ccsu.edu/assemblytutorial/index.html