Почему это утверждение карты в Perl не компилируется?

Question

Это не удается:

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { "prefix-$_" => 1 } @a; 

с этой ошибкой:

Not enough arguments for map at foo.pl line 4, near "} @a" 

, но это работает:

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { "prefix-" . $_ => 1 } @a; 

почему?

Answer 1

Поскольку Perl угадывает EXPR (например, хеш-ссылку) вместо BLOCK. Это должно работать (обратите внимание на символ '+'):

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { +"prefix-$_" => 1 } @a; 

См http://perldoc.perl.org/functions/map.html.

Answer 2

От perldoc -f map:

  "{" starts both hash references and blocks, so "map { ..." 
      could be either the start of map BLOCK LIST or map EXPR, LIST. 
      Because perl doesn’t look ahead for the closing "}" it has to 
      take a guess at which its dealing with based what it finds just 
      after the "{". Usually it gets it right, but if it doesn’t it 
      won’t realize something is wrong until it gets to the "}" and 
      encounters the missing (or unexpected) comma. The syntax error 
      will be reported close to the "}" but you’ll need to change 
      something near the "{" such as using a unary "+" to give perl 
      some help: 

      %hash = map { "\L$_", 1 } @array # perl guesses EXPR. wrong 
      %hash = map { +"\L$_", 1 } @array # perl guesses BLOCK. right 
      %hash = map { ("\L$_", 1) } @array # this also works 
      %hash = map { lc($_), 1 } @array # as does this. 
      %hash = map +(lc($_), 1), @array # this is EXPR and works! 
      %hash = map (lc($_), 1), @array # evaluates to (1, @array) 

      or to force an anon hash constructor use "+{" 

      @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end 

      and you get list of anonymous hashes each with only 1 entry. 

Answer 3

Я предпочитаю писать, что, как

my %h = map { ("prefix-$_" => 1) } @a; 

показать намерение, что я возвращал список, состоящий из 2-элемента.

Answer 4

Кроме того, другой способ сделать то, что вы делаете, инициализации хэша, вы можете сделать так:

my @a = qw(a b c d e); 
my %h; 
@h{@a} =(); 

Это создаст UNDEF записи для каждого из пяти ключей. Если вы хотите дать им все истинные ценности, сделайте это.

@h{@a} = (1) x @a; 

Вы также можете сделать это с помощью петли;

@h{$_} = 1 for @a; 

Answer 5

Я думаю, что

map { ; "prefix-$_" => 1 } @a; 

более идиоматических, насколько указав, что это блок операторов, а не хэш исх. Вы просто пинаете его нулевым утверждением.