ищет простой переключатель между «write to STDOUT» и «write to outfile»

Question

для программы, которую я пытаюсь написать в perl прямо сейчас, я хочу построить опцию, которая выводит вывод в выходной файл, что довольно легко с Perl-модулем Getopt. однако, если опция не используется, я хотел бы, чтобы выход перешел на терминал (STDOUT). для этого я написал небольшой скрипт, чтобы проверить, могу ли я построить коммутатор с модулем IO :: File.

#!/usr/bin/env perl 
use strict; 
use warnings; 
use Getopt::Long; 
use IO::File; 

my $outfilename; 

GetOptions (
    "out=s" => \$outfilename, 
); 

my $out = IO::File->new(">$outfilename"); 

if (defined $out) { 
    print $out "Hello World!\n"; 
} 
else { 
    print "Hello World!\n"; 
} 

close $out if $outfilename; 

хотя программа «прогонов» с или без опции -o, когда я запустить его без -o, Perl говорит мне, что $ outfilename в строке 13 не инициализирована, который я предполагаю, потому что Getopt возвращает переменные как «false», когда опция не используется. однако, я не могу придумать способ обойти это. Можете ли вы, ребята, помочь мне?
также, я абсолютно уверен, что есть гораздо более простой способ построить такой коммутатор, о котором я не знаю. я просто писал это, потому что я не мог найти лучшего способа в Интернете, поэтому, если у вас есть какие-то советы о том, как сделать это умнее, я был бы очень благодарен!

Answer 1

Вы получаете предупреждение, потому что вы используете $outfilename в качестве имени файла безусловно, даже если он имеет только значение, когда --out было предусмотрено.

Не помещайте весь print в if. Если вы это сделаете, вы получите много дублированного кода. Либо создать дескриптор файла, который инициализирован при любых условиях

my $outfh; 
if (defined($outfilename)) { 
    open($outfh, '>', $outfilename) 
     or die($!); 
} else { 
    $outfh = \*STDOUT; 
} 

print $outfh "Hello World!\n"; 

или перенаправить STDOUT

if (defined($outfilename)) { 
    open(STDOUT, '>', $outfilename) 
     or die($!); 
} 

print "Hello World!\n"; 

Но почему вы не перенаправление STDOUT с внешней стороны?

script >script.log 

Answer 2

Вы можете просто заменить STDOUT на ваш дескриптор файла, а затем распечатать его в обычном режиме.

if($outfilename) { 
    open my $of, ">", $outfilename; 
    *STDOUT = $of; 
} 

print "Hello World!\n"; 

Answer 3

Вы можете использовать select для установки выходного файла по умолчанию дескриптор с. Это приведет к тому, что print автоматически распечатает дескриптор файла select.

if ($outfilename) { 
    open my $outfh, ">", $outfilename 
     or die "Cannot open $outfilename for output: $!"; 
    select $outfh; 
} 

print "Hello world!\n"; 

Answer 4

Вы бы лучше взглянуть на следующем:

• http://perldoc.perl.org/functions/select.html
• http://perldoc.perl.org/SelectSaver.html

select вызова позволяет переопределить, что по умолчанию файл обработчик для print звонки. SelectSaver позволяет делать то же самое в области заданного блока кода.

В вашем случае вы можете переписать свой код, чтобы при необходимости создать дескриптор выходного файла, и select, прежде чем запускать код, который будет выполнять вывод. Код вывода, в свою очередь, просто вызовет print без дескриптора файла.