Как обернуть все методы обслуживания Grails с помощью Groovy закрытия?

Question

Grails 2.4.x здесь.

У меня есть требование, что все методы всех моих Grails услуг, порожденные grails create-service <xyz>, быть "обернутый"/перехвачены со следующей логикой:

try { 
    executeTheMethod() 
} catch(MyAppException maExc) { 
    log.error(ExceptionUtils.getStackTrace(maExc)) 
    myAppExceptionHandler.handleOrRethrow(maExc) 
} 

Где:

• log.error(...) является предоставленный SLF4J логгер, который вы получаете, когда вы комментируете свой класс с помощью аннотации @Slf4j; и
• ExceptionUtils - это номер от org.apache.commons:commons-lang3:3.4; и
• myAppExceptionHandler имеет тип com.example.myapp.MyAppExceptionHandler; и
• Такое поведение существует (или имеет возможность существовать в том случае, если она должна быть явно называется как-то) для каждого метода, определенного в службе Grails

Так, очевидно, это обертка код должен включать import заявления для этих классов.

Так, например, если у меня есть WidgetService, который выглядит следующим образом:

class WidgetService { 
    WidgetDataService widgetDataService = new WidgetDataService() 

    Widget getWidgetById(Long widgetId) { 
     List<Widget> widgets = widgetDataService.getAllWidgets() 
     widgets.each { 
      if(it.id.equals(widgetId)) { 
       return it 
      } 
     } 

     return null 
    } 
} 

Затем после этого Groovy/Grails/закрытие магия происходит мне нужен код ведут себя так, как будто я написал это нравится:

import groovy.util.logging.Slf4j 
import org.apache.commons.lang3.exception.ExceptionUtils 
import com.example.myapp.MyAppExceptionHandler 

@Slf4j 
class WidgetService { 
    WidgetDataService widgetDataService = new WidgetDataService() 

    MyAppExceptionHandler myAppExceptionHandler = new MyAppExceptionHandler() 

    Widget getWidgetById(Long widgetId) { 
     try { 
      List<Widget> widgets = widgetDataService.getAllWidgets() 
      widgets.each { 
       if(it.id.equals(widgetId)) { 
        return it 
       } 
      } 

      return null 
     } catch(MyAppException maExc) { 
      log.error(ExceptionUtils.getStackTrace(maExc)) 
      myAppExceptionHandler.handleOrRethrow(maExc) 
     } 
    } 
} 

Любые идеи относительно того, как я мог бы это достичь? Я волнуюсь, что чистая закрытие Groovy может каким-то образом вмешаться в то, что Grails делает со своими сервисами под капотом во время выполнения (так как это все классы, которые явно не распространяют родительский класс).

Answer 1

Вот что я пытался придавить точку в мой комментарий:

package com.example 

import groovy.util.logging.Log4j 

@Log4j 
trait SomeTrait { 

    def withErrorHandler(Closure clos) { 
     try { 
      clos() 
     } catch(Exception e) { 
      log.error e.message 
      throw new ApplicationSpecificException(
       "Application Specific Message: ${e.message}" 
      ) 
     } 
    } 
} 

Класс обслуживания:

package com.example 

class SampleService implements SomeTrait { 

    def throwingException() { 
     withErrorHandler { 
      throw new Exception("I am an exception") 
     } 
    } 

    def notThrowingException() { 
     withErrorHandler { 
      println "foo bar" 
     } 
    } 
} 

Тест:

package com.example 

import grails.test.mixin.TestFor 
import spock.lang.Specification 

@TestFor(SampleService) 
class SampleServiceSpec extends Specification { 

    void "test something"() { 
     when: 
     service.throwingException() 

     then: 
     ApplicationSpecificException e = thrown(ApplicationSpecificException) 
     e.message == "Application Specific Message: I am an exception" 
    } 

    void "test something again"() { 
     when: 
     service.notThrowingException() 

     then: 
     notThrown(Exception) 
    } 
} 

Вот sample app.

Grails 3.0.9, но это не должно иметь значения. это применимо для Grails 2.4. *

Answer 2

Вы можете перехватить вызовы методам класса обслуживания либо с помощью MetaInjection, либо Spring AOP. Поэтому вам не нужно писать закрытие в каждом классе службы. Вы можете посмотреть на этот blog, который объясняет оба подхода с примерами.