Передача параметров сценарию CGI с использованием flex

Я пытаюсь передать три параметра (arg1, arg2 и arg3) в CGI-скрипт, но следующий код не работает.Передача параметров сценарию CGI с использованием flex

Может ли кто-нибудь показать мне, как передать параметры сценарию CGI с использованием flex?

public function loadURL():void { 
    //frameBuffer.reloadFrame(frameBuffer.currentFrame); 
    var variables:URLVariables = new URLVariables("name=Franklin"); 
    var request:URLRequest = new URLRequest(); 
    request.url = "http://firefly.cs.missouri.edu/cgi-bin/main2.cgi?arg1=image.TIF&arg2=BranchPoints.txt&arg3=Medial.txt"; 
    request.method = URLRequestMethod.POST; 
    request.data = variables; 
    var loader:URLLoader = new URLLoader(); 
    loader.dataFormat = URLLoaderDataFormat.VARIABLES; 
    loader.addEventListener(Event.COMPLETE, completeHandler); 
    try 
    { 
     loader.load(request); 
    } 
    catch (error:Error) 
    { 
     trace("Unable to load URL"); 
    } 

    function completeHandler(event:Event):void 
    { 
     trace(event.target.data.welcomeMessage); 
    } 
    //Alert.show("Hi"); 
}

источник

2013-03-16 user1733735

Делают это так:

<?xml version="1.0" encoding="utf-8"?> 
<mx:Application 
xmlns:mx="http://www.adobe.com/2006/mxml" 
layout="absolute" minWidth="955" minHeight="600" creationComplete="init(event)"> 

<mx:Script> 
    <![CDATA[ 
     import mx.events.FlexEvent; 

     public function loadURL():void 
     { 
      var variables:URLVariables = new URLVariables(); 

      variables.name = "Franklin"; 
      variables.arg1 = "image.TIF"; 
      variables.arg2 = "BranchPoints.txt"; 
      variables.arg3 = "Medial.txt"; 

      var request:URLRequest = new URLRequest("http://firefly.cs.missouri.edu/cgi-bin/main2.cgi"); 
      request.method = "POST"; 
      request.data = variables; 

      var loader:URLLoader = new URLLoader(); 
      loader.dataFormat = URLLoaderDataFormat.TEXT; 
      loader.addEventListener(Event.COMPLETE, completeHandler); 
      loader.addEventListener(IOErrorEvent.IO_ERROR, onError); 

      loader.load(request); 
     } 

     private function completeHandler(event:Event):void 
     { 
      trace(event.target.data.welcomeMessage); 
     } 

     private function onError(event:IOErrorEvent):void 
     { 
      trace("Fault!"); 
     } 

     protected function init(event:FlexEvent):void 
     { 
      loadURL(); 
     } 

    ]]> 
</mx:Script> 

</mx:Application>

сценарий вернул мне следующий код:

<html><head><title>My First Script</title></head> 
<body> 
<p>Hello world!</p> 
</body></html>image.TIFBranchPoints.txtMedial.txtimage.TIF BranchPoints.txt Medial.txt

источник

2013-03-17 13:44:40 Anton

Передача параметров сценарию CGI с использованием flex

ответ

Смежные вопросы