Оценка [] кажется, не работает внутри кнопки []

Question

Любая идея, как заставить это работать?

y = {}; Table[Button[x, AppendTo[y, Evaluate[x]]], {x, 5}] 

Результат: Нажмите кнопку [1], нажмите [2], получить {6,6}

Я тривиализующее реальную задачу, но цель состоит в том, чтобы установить, что кнопка делает Внутри Map или Table или ParallelTable.

Пожалуйста, помогите!

---

EDIT
Фигурные это ... Evaluate работает только на первом уровне. Здесь он слишком глубокий. Поэтому я использовал ReplaceRule:

Remove[sub]; y = {}; Table[Button[x, AppendTo[y, sub]] /. sub -> x, {x, 5}] 

Answer 1

Замена и чистые функции предлагают краткие альтернативы With. Например:

y={}; Range[5] /. x_Integer :> Button[x, AppendTo[y, x]] 

или

y = {}; Replace[Range[5], x_ :> Button[x, AppendTo[y, x]], {1}] 

или

y = {}; Array[Button[#, AppendTo[y, #]] &, {5}] 

или

y = {}; Button[#, AppendTo[y, #]] & /@ Range[5] 

В другом примере сравнения этих методов, см мой пост here, где они применяются к проблеме лемму о создании списка чистых функций с параметром, встроенным в их тело (замыкания).

Answer 2

Это работа для With. With используется для вставки оцененной выражение в другое выражение на любой глубине - даже в части выражения, которые не оцениваются сразу, как второй аргумент Button:

y = {}; Table[With[{x = i}, Button[x, AppendTo[y, x]]], {i, 5}] 

В простых случаях, подобных этому, некоторые люди (включая меня) предпочитают использовать один и тот же символ (x в данном случае) для обоих With и Table переменных, таким образом: правила

y = {}; Table[With[{x = x}, Button[x, AppendTo[y, x]]], {x, 5}] 

Answer 3

Evaluate работает только на первом уровне. Здесь он слишком глубокий. Поэтому я использовал ReplaceRule:

Remove[sub]; y = {}; Table[ Button[x, AppendTo[y, sub]] /. sub -> x, {x, 5}]