Haskell Aeson: Как преобразовать значение в пользовательский тип?

Question

Невозможно найти хороший пример. Цените любую помощь. JSON выглядит следующим образом:

[{ 
    "EXIF:Make": "Canon", 
    "EXIF:Model": "Canon PowerShot S95", 
    "EXIF:Orientation": "Horizontal (normal)", 
    "EXIF:XResolution": 180, 
    "EXIF:YResolution": 180, 
    "EXIF:ResolutionUnit": "inches" 
}] 

код, который я использовал это следующим образом:

import Data.Aeson 
import Data.Attoparsec 
import Data.ByteString 
x <- fmap (parse json) (Data.ByteString.readFile "json.txt") 

Как определить & использовать FromJSON типа для преобразования из x в:

data Exif = Exif [[(String, String)]] 

или аналогичной структуры данных? Обратите внимание на [[]]. Я ожидаю, что JSON будет иметь несколько записей верхнего уровня.

Answer 1

Вот идиоматическое решение:

{-# LANGUAGE OverloadedStrings #-} 

module Main 
     where 

import Control.Applicative 
import Control.Monad 
import Data.Aeson 
import Data.Attoparsec 

import qualified Data.ByteString as B 
import qualified Data.Text as T 

data ExifEntry = ExifEntry { exifMake :: T.Text, 
          exifModel :: T.Text, 
          exifOrientation :: T.Text, 
          exifXResolution :: Int, 
          exifYResolution :: Int, 
          exifResolutionUnit :: T.Text 
          } deriving (Eq, Show) 


instance FromJSON ExifEntry 
    where 
    parseJSON (Object v) = ExifEntry <$> 
          v .: "EXIF:Make" <*> 
          v .: "EXIF:Model" <*> 
          v .: "EXIF:Orientation" <*> 
          v .: "EXIF:XResolution" <*> 
          v .: "EXIF:YResolution" <*> 
          v .: "EXIF:ResolutionUnit" 
    parseJSON _   = mzero 


parseAll :: B.ByteString -> [ExifEntry] 
parseAll s = case (parse (fromJSON <$> json) s) of 
    Done _ (Error err) -> error err 
    Done ss (Success e) -> e:(parseAll ss) 
    _     -> [] 

main :: IO() 
main = do s <- B.readFile "json.txt" 
      let p = parseAll s 
      print p 

Тестирование:

$ cat json.txt 
{ 
    "EXIF:Make": "Canon", 
    "EXIF:Model": "Canon PowerShot S95", 
    "EXIF:Orientation": "Horizontal (normal)", 
    "EXIF:XResolution": 180, 
    "EXIF:YResolution": 180, 
    "EXIF:ResolutionUnit": "inches" 
} 

{ 
    "EXIF:Make": "Canon", 
    "EXIF:Model": "Canon PowerShot S995", 
    "EXIF:Orientation": "Horizontal (normal)", 
    "EXIF:XResolution": 180, 
    "EXIF:YResolution": 180, 
    "EXIF:ResolutionUnit": "inches" 
} 
$ ./dist/build/test/test 
[ExifEntry {exifMake = "Canon", exifModel = "Canon PowerShot S95", exifOrientation = "Horizontal (normal)", exifXResolution = 180, exifYResolution = 180, exifResolutionUnit = "inches"},ExifEntry {exifMake = "Canon", exifModel = "Canon PowerShot S995", exifOrientation = "Horizontal (normal)", exifXResolution = 180, exifYResolution = 180, exifResolutionUnit = "inches"}] 

В качестве альтернативы, вот slightly more ugly solution, что дает вам данные типа вы запросили ([[(Text,Text)]]).