QML: Как отказаться от действия капли

Question

У меня есть один DropArea и два элемента. Я хочу, чтобы DropArea отклонил событие перетаскивания, если DropArea уже получил один элемент, который должен быть удален, а другой элемент не разрешает вбрасывать, если только первый не выйдет.

DropArea { 
    property bool dropped: false 

    onDropped: { 
     drop.accepted = !dropped; 
     dropped = true; 
    } 
    onExited: dropped = false 
} 

Но похож drop.accepted не работает, BTW в любом случае, чтобы получить объекты были сброшены в DropArea

Answer 1

Вы должны контролировать, если элемент должен быть удален или не onReleased, проверяя dropped свойство.

Полный пример:

import QtQuick 2.5 
import QtQuick.Window 2.2 
import QtQuick.Controls 1.4 

Window { 
    id: win 
    visible: true 
    width: 800 
    height: 600 
    title: qsTr("Hello World") 

    Repeater { 
     model: 10 
     Rectangle { 
      id: rect 
      width: 50 
      height: 50 
      z: mouseArea.drag.active || mouseArea.pressed ? 2 : 1 
      color: Qt.rgba(Math.random(), Math.random(), Math.random(), 1) 
      x: Math.random() * (win.width/2 - 100) 
      y: Math.random() * (win.height - 100) 
      property point beginDrag 
      property bool caught: false 
      border { width:2; color: "white" } 
      radius: 5 
      Drag.active: mouseArea.drag.active 

      Text { 
       anchors.centerIn: parent 
       text: index 
       color: "white" 
      } 
      MouseArea { 
       id: mouseArea 
       anchors.fill: parent 
       drag.target: parent 
       onPressed: { 
        rect.beginDrag = Qt.point(rect.x, rect.y); 
       } 
       onReleased: { 
        if(!rect.caught || dragTarget.dropped) { 
         backAnimX.from = rect.x; 
         backAnimX.to = beginDrag.x; 
         backAnimY.from = rect.y; 
         backAnimY.to = beginDrag.y; 
         backAnim.start() 
        } 

        parent.Drag.drop() 

        console.log("MouseArea - containsDrag " + dragTarget.dropped) 
       } 

      } 
      ParallelAnimation { 
       id: backAnim 
       SpringAnimation { id: backAnimX; target: rect; property: "x"; 
            duration: 500; spring: 2; damping: 0.2 } 
       SpringAnimation { id: backAnimY; target: rect; property: "y"; 
            duration: 500; spring: 2; damping: 0.2 } 
      } 
     } 
    } 

    Rectangle { 
     anchors { 
      top: parent.top 
      right: parent.right 
      bottom: parent.bottom 
     } 
     width: parent.width/2 
     color: "gold" 
     DropArea { 
      id: dragTarget 
      anchors.fill: parent 

      property bool dropped: false 

      onEntered: { 
       console.log("onEntered " + containsDrag) 
       drag.source.caught = true; 
      } 
      onExited: { 
       console.log("onExited " + containsDrag) 
       dropped = false; 
      } 
      onDropped: 
      { 
       console.log("onDropped"); 
       dropped = true; 
      } 
     } 
    } 
} 

Answer 2

Используйте drop.accept() вместо этого. Выше, может быть сделано следующим образом:

property bool containsItem: false 
DropArea { 
    id: dropArea 
    anchors.fill: parent 
    onDropped: { 
     if(containsItem) 
      drop.accept(Qt.IgnoreAction) 
     else 
      drop.accept() 

     containsItem = true; 
    } 
} 

Также используйте выигрыш dropped свойства, как это уже вложенное свойство внутри onDropped обработчика событий.

Edit: Если rect является Пункт перетаскиваться затем:

Rectangle { 
    id: rect 
    width: 40; height: 40 
    color: "red" 

    Drag.active: dragArea.drag.active 
    Drag.hotSpot.x: 20 
    Drag.hotSpot.y: 20 

    MouseArea { 
     id: dragArea 
     anchors.fill: parent 
     drag.target: parent 
     onReleased: if (rect.Drag.drop() !== Qt.IgnoreAction) { 
         console.log("Accepted!"); 
        } else { 
         console.log("Rejected!"); 
        } 
    } 
}