Флажки проверяются на основе файла и хранятся в файле в as3

Question

У меня есть 5 флажков, 1 кнопка и текстовый файл. В моем текстовом файле значение сохраняется, как это:

1,0,0,0,1

Когда я запускаю программу, первые и последние Флажки должны быть проверены и другими должна быть сняты.

Если я установил или снял отметку с любого из флажков, затем нажмите кнопку сохранения, измененные значения должны быть обновлены в текстовом файле. Как я могу достичь этого?

Answer 1

var filename:String = "checkboxes.txt"; 
var checkboxes:Vector.<CheckBox> = new <CheckBox>[checkbox1, checkbox2, etc]; 

function load():void { 
    // read text file 
    var file:File = File.applicationStorageDirectory.resolvePath(filename); 
    if(!file.exists) 
     return; 
    var fileStream:FileStream = new FileStream(); 
    fileStream.open(file, FileMode.READ); 
    var text:String = fileStream.readUTFBytes(fileStream.bytesAvailable); 
    fileStream.close(); 

    // decode text values to checkboxes 
    var values:Array = text.split(","); 
    for(var i:int = 0; i < values.length; i++){ 
     var checked:Boolean = values[i] == "1"; 
     checkboxes[i].selected = checked; 
    } 
} 

function save():void { 
    // encode checkboxes to text 
    var values:Array = []; 
    for(var i:int = 0; i < checkboxes.length; i++){ 
     values.push(int(checkboxes[i].selected)); 
    } 
    var text:String = values.join(","); 

    // write to file 
    var file:File = File.applicationStorageDirectory.resolvePath(filename); 
    var fileStream:FileStream = new FileStream(); 
    fileStream.open(file, FileMode.WRITE); 
    fileStream.writeUTFBytes(text); 
    fileStream.close(); 
}