Haskell Йесод - CORS проблемы с браузерами OPTIONS запросов при выполнении POST запросы

Question

Я использовал Network.Wai.Middleware.Cors «s simpleCors, она работала должным образом для GET запросов, но когда я пытаюсь сделать POST запрос я получаю следующую задачу

OPTIONS /users 
    Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8 
    Status: 400 Bad Request 0.032443s 

единственный способ, которым я был в состоянии сделать это работа удалением simpleCors из следующей части в Application.hs

-- | Convert our foundation to a WAI Application by calling @toWaiAppPlain@ and 
-- applying some additional middlewares. 
makeApplication :: App -> IO Application 
makeApplication foundation = do 
    logWare <- makeLogWare foundation 
    -- Create the WAI application and apply middlewares 
    appPlain <- toWaiAppPlain foundation 
    return $ logWare $ defaultMiddlewaresNoLogging $ simpleCors $ appPlain 

и добавив OPTIONS Метод ответа

optionsNewUserR :: Handler RepPlain 
optionsNewUserR = do 
    return $ RepPlain $ toContent ("" :: Text) 

и добавление заголовков CORS ... Но это грязное решение, потому что я должен был бы изменить все мои обработчики API! Любая помощь высоко ценится!

Answer 1

Я считаю, что проблема заключается в том, что simpleCors построен вне simpleCorsResourcePolicy, который охватывает только simpleMethods, который не охватывает OPTIONS.

Вы можете исправить эту проблему, используя те же методы, что и рулон любого необходимого промежуточного программного обеспечения.

Вот один я использую для OPTIONS проблемы вы описали:

{-# LANGUAGE OverloadedStrings #-} 

module Middlewares where 

import Network.Wai      (Middleware) 
import Network.Wai.Middleware.AddHeaders (addHeaders) 
import Network.Wai.Middleware.Cors  (CorsResourcePolicy(..), cors) 

-- | @x-csrf-token@ allowance. 
-- The following header will be set: @Access-Control-Allow-Headers: x-csrf-token@. 
allowCsrf :: Middleware 
allowCsrf = addHeaders [("Access-Control-Allow-Headers", "x-csrf-token,authorization")] 

-- | CORS middleware configured with 'appCorsResourcePolicy'. 
corsified :: Middleware 
corsified = cors (const $ Just appCorsResourcePolicy) 

-- | Cors resource policy to be used with 'corsified' middleware. 
-- 
-- This policy will set the following: 
-- 
-- * RequestHeaders: @Content-Type@ 
-- * MethodsAllowed: @OPTIONS, GET, PUT, POST@ 
appCorsResourcePolicy :: CorsResourcePolicy 
appCorsResourcePolicy = CorsResourcePolicy { 
    corsOrigins  = Nothing 
    , corsMethods  = ["OPTIONS", "GET", "PUT", "POST"] 
    , corsRequestHeaders = ["Authorization", "Content-Type"] 
    , corsExposedHeaders = Nothing 
    , corsMaxAge   = Nothing 
    , corsVaryOrigin  = False 
    , corsRequireOrigin = False 
    , corsIgnoreFailures = False 
} 

А потом просто сочинить вам нужно промежуточное программное как вы уже делаете:

run port $ logger . allowCsrf . corsified $ app cfg