Perl: удаление элементов массива и изменение размера массива

Question

Я пытаюсь отфильтровать массив терминов, используя другой массив в Perl. У меня Perl 5.18.2 на OS X, хотя поведение такое же, если я use 5.010. Вот моя основная установка:

#!/usr/bin/perl 
#use strict; 
my @terms = ('alpha','beta test','gamma','delta quadrant','epsilon', 
      'zeta','eta','theta chi','one iota','kappa'); 
my @filters = ('beta','gamma','epsilon','iota'); 
foreach $filter (@filters) { 
    for my $ind (0 .. $#terms) { 
     if (grep { /$filter/ } $terms[$ind]) { 
      splice @terms,$ind,1; 
     } 
    } 
} 

Это работает, чтобы вытащить строки, которые соответствуют различным условиям поиска, но длина массива не изменяется. Если я выписывать в результате @terms массив, я получаю:

[alpha] 
[delta quadrant] 
[zeta] 
[eta] 
[theta chi] 
[kappa] 
[] 
[] 
[] 
[] 

Как и следовало ожидать от этого, печать scalar(@terms) получает результат 10.

Я хочу получить результирующий массив длиной 6, без четырех пустых элементов в конце. Как получить этот результат? И почему матрица не уменьшается, учитывая, что perldoc page about splice говорит: «Массив растет или сжимается по мере необходимости»?

(Я не очень свободно владею Perl, поэтому, если вы думаете: «Почему бы вам не просто ...?», Это почти наверняка, потому что я не знаю об этом или не понимаю его когда я услышал об этом.)

Answer 1

Вы всегда можете восстановить массив за вычетом того, чего не хотите. grep действует как фильтр позволяет вам решить, какие элементы вы хотите, и которые вы не:

#!/usr/bin/perl 

use strict; 

my @terms = ('alpha','beta test','gamma','delta quadrant','epsilon', 
      'zeta','eta','theta chi','one iota','kappa'); 
my @filters = ('beta','gamma','epsilon','iota'); 

my %filter_exclusion = map { $_ => 1 } @filters; 

my @filtered = grep { !$filter_exclusion{$_} } @terms; 

print join(',', @filtered) . "\n"; 

Это довольно легко, если у вас есть простая структура, как %filter_exclusion на руку.

Update: Если вы хотите, чтобы произвольно подстрок:

my $filter_exclusion = join '|', map quotemeta, @filters; 

my @filtered = grep { !/$filter_exclusion/ } @terms; 

Answer 2

Чтобы понять, что происходит, вывести содержимое массива на каждом шаге: Когда вы сращивание массив, она сжимается, но ваша петля повторяется над 0 .. $ # членами, поэтому в конце цикла $ ind будет указывать за конец массива. Когда вы используете grep { ... } $array[ $too_large ], Perl должен иметь псевдоним несуществующего элемента в $_ внутри блока grep, поэтому он создает элемент undef в массиве.

#!/usr/bin/perl 
use warnings; 
use strict; 
use feature qw{ say }; 

my @terms = ('alpha', 'beta test', 'gamma', 'delta quadrant', 'epsilon', 
      'zeta', 'eta', 'theta chi', 'one iota', 'kappa'); 
my @filters = qw(beta gamma epsilon iota); 

for my $filter (@filters) { 
    say $filter; 
    for my $ind (0 .. $#terms) { 
     if (grep { do { 
      no warnings 'uninitialized'; 
      /$filter/ 
     } } $terms[$ind] 
     ) { 
      splice @terms, $ind, 1; 
     } 
     say "\t$ind\t", join ' ', map $_ || '-', @terms; 
    } 
} 

Если вы использовали $terms[$ind] =~ /$filter/ вместо grep, вы все равно получите неинициализированным предупреждение, но нет никакой необходимости псевдонима элемента, он не будет создан.